File Coverage

blib/lib/smartmatch.pm

Criterion	Covered	Total	%
statement	54	57	94.7
branch	5	8	62.5
condition			n/a
subroutine	15	17	88.2
pod	2	2	100.0
total	76	84	90.4

package smartmatch;
BEGIN {
  $smartmatch::AUTHORITY = 'cpan:DOY';
}
{
  $smartmatch::VERSION = '0.05'; # TRIAL
}
use strict;
use warnings;
use 5.010;
# ABSTRACT: pluggable smart matching backends

use parent 'DynaLoader';
use B::Hooks::OP::Check;
use Module::Runtime 'use_package_optimistically';
use Package::Stash;

sub dl_load_flags { 0x01 }

__PACKAGE__->bootstrap(
    # we need to be careful not to touch $VERSION at compile time, otherwise
    # DynaLoader will assume it's set and check against it, which will cause
    # fail when being run in the checkout without dzil having set the actual
    # $VERSION
    exists $smartmatch::{VERSION}
        ? ${ $smartmatch::{VERSION} } : (),
);


my $anon = 1;

sub import {
    my $package = shift;
    my ($engine) = @_;

    if (ref($engine)) {
        my $cb = $engine;
        $engine = '__ANON__::' . $anon++;
        my $anon_stash = Package::Stash->new("smartmatch::engine::$engine");
        $anon_stash->add_symbol('&match' => $cb);
    }
    else {
        my $package = "smartmatch::engine::$engine";
        use_package_optimistically($package);
        die "$package does not implement a 'match' function"
            unless $package->can('match');
    }

    $^H{'smartmatch/engine'} = $engine;
}

sub unimport {
    delete $^H{'smartmatch/engine'};
}


sub callback_at_level {
    my ($level) = @_;
    $level++;
    my $hh = (caller($level))[10];
    my $engine = $hh ? $hh->{'smartmatch/engine'} : undef;

    my $recurse;
    if ($engine) {
        $recurse = eval <<"RECURSE";
            use smartmatch '$engine';
            sub { \$_[0] ~~ \$_[1] }
RECURSE
    }
    else {
        $recurse = sub { $_[0] ~~ $_[1] };
    }

    return $recurse;
}


1;

__END__