File Coverage

blib/lib/lib/vendor.pm

Criterion	Covered	Total	%
statement	31	36	86.1
branch	9	14	64.2
condition	4	9	44.4
subroutine	7	7	100.0
pod	0	1	0.0
total	51	67	76.1

use v5.10;

package lib::vendor;
# ABSTRACT: add vendor libraries to the module search path (@INC)
our $VERSION = '0.14.163'; # VERSION

use strict;

use FindBin     ();
use File::Spec  ();

# File layout could be:
# .
# +- bin
# +- lib
# +- vendor
# +- ...
#
# Or:
#
# .
# +- lib
# +- vendor
# +- ...

our $APPDIR;
BEGIN {
    if ( not $APPDIR ) {
        $APPDIR = $FindBin::RealBin;
        while ( $APPDIR ne '/' && !-d File::Spec->catdir( $APPDIR, 'lib' ) ) {
            # Search upwards in the directory structure
            # until we find a subdirectory named 'lib'.
            my @appdir = File::Spec->splitdir($APPDIR);
            pop @appdir;
            $APPDIR = File::Spec->catdir(@appdir);
        }
    }
}

our $VENDOR //= 'vendor';
sub import {
    my ( $package, @vendors ) = @_;

    if ( @vendors ) {
        if ( defined $vendors[0] && $vendors[0] eq '-vendor' ) {
            ( undef, my $vendor, @vendors ) = @vendors;
            $VENDOR = $vendor if defined $vendor;
        }

        for my $vendor (@vendors) {
            $vendor = File::Spec->catdir( $APPDIR, $VENDOR, $vendor, 'lib' );
        }
    }
    unshift @vendors, File::Spec->catdir( $APPDIR, "lib" );

    shrink_INC(@vendors);
}

sub shrink_INC {
    local $_;
    my %seen = ();
    @INC = grep {
        my $key;
        if ( ref($_) ) {
            # If it's a ref, key on the memory address.
            $key = int $_;
        } elsif ( $^O ne 'MSWin32' and my ($dev, $inode) = stat($_) ) {
            # If it's on the filesystem, key on the combo of dev and inode,
            # which is not valid on MSWin32.
            $key = join( _ => $dev, $inode );
        } else {
            # Otherwise, key on the element.
            $key = $_;
        }
        $key && !$seen{$key}++;
    } @_, @INC;
}

1;

__END__