File Coverage

blib/lib/Zabbix/Check/RabbitMQ.pm

Criterion	Covered	Total	%
statement	25	91	27.4
branch	0	32	0.0
condition	0	9	0.0
subroutine	8	17	47.0
pod	0	2	0.0
total	33	151	21.8

package Zabbix::Check::RabbitMQ;
=head1 NAME

Zabbix::Check::RabbitMQ - Zabbix check for RabbitMQ service

=head1 VERSION

version 1.10

=head1 SYNOPSIS

Zabbix check for RabbitMQ service

	UserParameter=cpan.zabbix.check.rabbitmq.installed,/usr/bin/perl -MZabbix::Check::RabbitMQ -e_installed
	UserParameter=cpan.zabbix.check.rabbitmq.running,/usr/bin/perl -MZabbix::Check::RabbitMQ -e_running
	UserParameter=cpan.zabbix.check.rabbitmq.vhost_discovery[*],/usr/bin/perl -MZabbix::Check::RabbitMQ -e_vhost_discovery -- $1
	UserParameter=cpan.zabbix.check.rabbitmq.queue_discovery[*],/usr/bin/perl -MZabbix::Check::RabbitMQ -e_queue_discovery -- $1
	UserParameter=cpan.zabbix.check.rabbitmq.queue_status[*],/usr/bin/perl -MZabbix::Check::RabbitMQ -e_queue_status -- $1 $2 $3

=head3 installed

checks RabbitMQ is installed: 0 | 1

=head3 running

checks RabbitMQ is installed and running: 0 | 1 | 2 = not installed

=head3 vhost_discovery $1

discovers RabbitMQ vhosts

$1: I

=head3 queue_discovery $1

discovers RabbitMQ queues

$1: I

=head3 queue_status $1 $2 $3

gets RabbitMQ queue status using queue discovery cache

$1: I

$2: I

$3: I

=cut
use strict;
use warnings;
no warnings qw(qw utf8);
use v5.14;
use utf8;
use Lazy::Utils;

use Zabbix::Check;


BEGIN
{
	require Exporter;
	# set the version for version checking
	our $VERSION     = '1.10';
	# Inherit from Exporter to export functions and variables
	our @ISA         = qw(Exporter);
	# Functions and variables which are exported by default
	our @EXPORT      = qw(_installed _running _vhost_discovery _queue_discovery _queue_status);
	# Functions and variables which can be optionally exported
	our @EXPORT_OK   = qw();
}


our ($rabbitmqctl) = whereisBin('rabbitmqctl');


sub getVhosts
{
	return unless $rabbitmqctl;
	my ($expiry) = @_;
	$expiry = -1 unless defined($expiry);
	my $result = fileCache("all", $expiry, sub
	{
		my $result = {};
		my $first = 1;
		for my $line (`$rabbitmqctl list_vhosts 2>/dev/null`)
		{
			chomp $line;
			if ($first)
			{
				$first = 0;
				next;
			}
			my ($name) = $line =~ /^(.*)/;
			$result->{$name} = { 'name' => $name };
		}
		return $result;
	});
	return $result;
}

sub getQueues
{
	return unless $rabbitmqctl;
	my ($vhost, $expiry) = @_;
	my $vhostS = shellmeta($vhost);
	$expiry = -1 unless defined($expiry);
	my $result = fileCache($vhost, $expiry, sub
	{
		my $result = {};
		my $first = 1;
		for my $line (`$rabbitmqctl list_queues -p \"$vhostS\" name messages_ready messages_unacknowledged messages 2>/dev/null`)
		{
			chomp $line;
			if ($first)
			{
				$first = 0;
				next;
			}
			my ($name, $ready, $unacked, $total) = $line =~ m/^([^\t]+)\t+([^\t]+)\t+([^\t]+)\t+([^\t]+)\t*/;
			$result->{$name} = {'ready' => $ready, 'unacked' => $unacked, 'total' => $total};
		}
		return $result;
	});
	return $result;
}

sub _installed
{
	my $result = $rabbitmqctl? 1: 0;
	print $result;
	return $result;
}

sub _running
{
	my $result = 2;
	if ($rabbitmqctl)
	{
		system "$rabbitmqctl cluster_status >/dev/null 2>&1";
		$result = ($? == 0)? 1: 0;
	}
	print $result;
	return $result;
}

sub _vhost_discovery
{
	my ($expiry) = map(zbxDecode($_), @ARGV);
	$expiry = 0 unless defined($expiry);
	my @items;
	my $vhosts = getVhosts($expiry);
	$vhosts = {} unless $vhosts;
	for my $vhost (keys %$vhosts)
	{
		push @items, { vhost => $vhost };
	}
	return printDiscovery(@items);
}

sub _queue_discovery
{
	my ($expiry) = map(zbxDecode($_), @ARGV);
	$expiry = 0 unless defined($expiry);
	my @items;
	my $vhosts = getVhosts($expiry);
	$vhosts = {} unless $vhosts;
	for my $vhost (keys %$vhosts)
	{
		my $queues = getQueues($vhost, $expiry);
		$queues = {} unless $queues;
		for my $queue (keys %$queues)
		{
			push @items, { vhost => $vhost, queue => $queue };
		}
	}
	return printDiscovery(@items);
}

sub _queue_status
{
	my ($vhost, $queue, $type) = map(zbxDecode($_), @ARGV);
	return unless $vhost and $queue and $type and $type =~ /^ready|unacked|total$/;
	my $result = "";
	my $queues = getQueues($vhost);
	$result = $queues->{$queue}->{$type} if defined($queues->{$queue}->{$type});
	print $result;
	return $result;
}


1;
__END__