File Coverage

blib/lib/WordListBase/MetaSyntactic.pm

Criterion	Covered	Total	%
statement	32	32	100.0
branch	6	8	75.0
condition	1	2	50.0
subroutine	9	9	100.0
pod	0	8	0.0
total	48	59	81.3

package WordListBase::MetaSyntactic;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2020-05-23'; # DATE
our $DIST = 'WordListBase-MetaSyntactic'; # DIST
our $VERSION = '0.007'; # VERSION

use strict 'subs', 'vars';

# IFUNBUILT
# use Role::Tiny::With;
# with 'WordListRole::WordList';
# END IFUNBUILT

sub new {
    my $package = shift;
    die "Must be subclassed by WordList::MetaSyntactic::*, not '$package'"
        unless $package =~ /\AWordList::MetaSyntactic::(\w+)\z/;
    require Acme::MetaSyntactic;
    bless {
        # Acme::MetaSyntactic object
        _am => Acme::MetaSyntactic->new($1),

        _iterator_idx => 0,

         # the whole array of words, for when iterating
        _all_words => undef,
    }, $package;
}

sub each_word {
    my ($self, $code) = @_;

    for my $word (sort $self->{_am}->name(0)) {
        $code->($word);
    }
}

sub pick {
    my ($self, $n) = @_;

    $n ||= 1;
    $self->{_am}->name($n);
}

sub word_exists {
    my ($self, $word) = @_;

    for my $w ($self->{_am}->name(0)) {
        return 1 if $word eq $w;
    }
    0;
}

sub all_words {
    my ($self) = @_;

    # A:M doesn't provide a method to get a sorted list, so we sort it ourselves
    sort $self->{_am}->name(0);
}

sub reset_iterator {
    my $self = shift;
    $self->{_iterator_idx} = 0;
}

sub next_word {
    my $self = shift;
    unless (defined $self->{_all_words}) {
        $self->{_all_words} = [$self->all_words];
    }
    my $word = $self->{_all_words}[ $self->{_iterator_idx} ];
    $self->{_iterator_idx}++;
    $self->{_iterator_idx} = 0
        if $self->{_iterator_idx} > @{ $self->{_all_words} };
    $word;
}

sub first_word {
    my $self = shift;
    $self->reset_iterator;
    $self->next_word;
}

1;
# ABSTRACT: Base class for WordList::MetaSyntactic::*

__END__