File Coverage

blib/lib/Win32/Vcpkg/List.pm

Criterion	Covered	Total	%
statement	58	61	95.0
branch	18	24	75.0
condition	9	12	75.0
subroutine	10	10	100.0
pod	4	4	100.0
total	99	111	89.1

package Win32::Vcpkg::List;

use strict;
use warnings;
use 5.008001;
use Win32::Vcpkg;
use Path::Tiny ();
use Storable qw( dclone );

# ABSTRACT: Interface to Microsoft Vcpkg List of Packages
our $VERSION = '0.02'; # VERSION


sub new
{
  my($class, %args) = @_;

  my $root = defined $args{root} ? Path::Tiny->new($args{root}) : Win32::Vcpkg->root;

  my $status = $root->child('installed', 'vcpkg', 'status');

  my @status;
  my %arch;
  {
    my %entry;

    foreach my $line ($status->lines)
    {
      chomp $line;
      if($line =~ /^(.*?):\s*(.*)$/)
      {
        my($k,$v) = ($1, $2);
        $entry{$k} = $v;
        $arch{$v}++ if $k eq 'Architecture';
      }
      elsif($line =~ /^\s*$/)
      {
        if(%entry)
        {
          push @status, dclone(\%entry);
          %entry = ();
        }
      }
    }

    if(%entry)
    {
      push @status, \%entry;
    }
  }

  bless {
    root     => $root,
    status   => \@status,
    triplets => [sort keys %arch],
  }, $class;
}


sub root { shift->{root} }


sub triplets { @{ shift->{triplets} } }


sub search
{
  my($self, $name, %options) = @_;
  my $triplet = $options{triplet} || Win32::Vcpkg->perl_triplet;
  my $debug   = defined $options{debug} ? $options{debug} : $ENV{PERL_WIN32_VCPKG_DEBUG};

  foreach my $status (@{ $self->{status} })
  {
    next unless $status->{Architecture} eq $triplet
    &&          $status->{Package} eq $name
    &&          !defined $status->{Feature}
    &&          $status->{Version};

    my $version = $status->{Version};
    my $file_list = $self->root->child('installed','vcpkg','info',sprintf("%s_%s_%s.list", $name, $version, $triplet));
    if($file_list->is_file)
    {
      my @lib;
      my $libpath = Path::Tiny->new($triplet, 'lib');
      $libpath = $libpath->parent->child('debug','lib') if $debug;
      foreach my $line ($file_list->lines)
      {
        chomp $line;
        my $path = Path::Tiny->new($line);
        if($path->basename =~ /^(.*?)\.lib$/)
        {
          if($path->parent->stringify eq $libpath->stringify)
          {
            push @lib, "$1";
          }
        }
      }
      require Win32::Vcpkg::Package;
      return Win32::Vcpkg::Package->new(
        _name    => $name,
        _version => $version,
        root     => $self->root,
        triplet  => $triplet,
        debug    => $debug,
        lib      => \@lib,
      );
    }
    else
    {
      require Carp;
      Carp::croak("unable to find file list for $name $version $triplet");
    }
  }

  return undef;
}


1;

__END__