File Coverage

blib/lib/WebService/Shutterstock/Exception.pm

Criterion	Covered	Total	%
statement	24	24	100.0
branch	2	4	50.0
condition	3	5	60.0
subroutine	7	7	100.0
pod	1	2	50.0
total	37	42	88.1

package WebService::Shutterstock::Exception;
{
  $WebService::Shutterstock::Exception::VERSION = '0.006';
}

# ABSTRACT: Exception object to allow for easy error handling on HTTP errors

use strict;
use warnings;

use Moo;
use overload q("") => \&to_string;


has request  => ( is => 'lazy', required => 0, handles => ['uri', 'method'] );
sub _build_request {
	my $self = shift;
	return $self->response ? $self->response->request : undef;
}


has response => ( is => 'ro', required => 0, handles => ['code'] );


has error    => ( is => 'ro', required => 1 );


has caller_info => ( is => 'ro', required => 1 );


sub BUILDARGS {
	my $class = shift;
	my $args = $class->SUPER::BUILDARGS(@_);
	my $level = 0;
	while(!$args->{caller_info} || $args->{caller_info}->{package} =~ /^(Sub::Quote|WebService::Shutterstock)/){
		my @info = caller($level++) or last;
		$args->{caller_info} = { package => $info[0], file => $info[1], line => $info[2] };
	}
	$args->{caller_info} ||= { package => 'N/A', file => 'N/A', line => -1 };
	return $args;
}


sub to_string {
	my $self = shift;
	return sprintf("%s at %s line %s.\n", $self->error, $self->caller_info->{file}, $self->caller_info->{line});
}

1;

__END__