File Coverage

blib/lib/WebService/Lobid/Organisation.pm

Criterion	Covered	Total	%
statement	64	76	84.2
branch	12	22	54.5
condition	1	3	33.3
subroutine	9	10	90.0
pod	0	1	0.0
total	86	112	76.7

package WebService::Lobid::Organisation;

our $VERSION = 0.005;

# ABSTRACT: interface to the lobid-Organisations API

=for html

=head1 NAME

WebService::Lobid::Organisation - interface to the lobid-Organisations API

=head1 SYNOPSIS

 my $Library = WebService::Lobid::Organisation->new(isil=> 'DE-380');

 if ($Library->status eq 'OK'){
  printf("This Library is called '%s', its homepage is at '%s'
          and it can be found at %f/%f",
          $Library->name, $Library->url, $Library->lat, $Library->long
          );

  if ($Library->has_wikipedia){
    printf("%s has its own wikipedia entry: %s",
      $Library->name, $Library->wikipedia);
    }

  if ($Library->has_multiple_emails){
    print $Library->email->[0];
  }else{
    print $Library->email;
  }
 }else{
    print $Library->error;
 }

=head1 METHODS

=over 4

=item new(isil=>$isil)

tries to fetch data for the organisation identified by the ISIL C<$isil>.
If an entry is found then the attribute C is set to I

If an error occurs, the attribute C is set to I with the error
message in C<$self->error>. Otherwise C is I.

=back

=head1 ATTRIBUTES

currently the following attributes are supported

=over 4

=item * B

inherited from L, default is I

=item * B

inherited from L, I if C reachable,
otherwise C

=item * B

inherited from L, default ist I<3> seconds


=item * B

inherited from L, I if L can use SSL,
otherwise C

=item * B (true|false)

indicates if an entry is found

=item * B

the L of the organisation. Has the predicate function I.

=item * B

Has the predicate function I.

=item * B

Has the predicate function I

=item * B

Service URL, normally the OPAC, Has the predicate function I

=item * B

Has the predicate function I

=item * B

The city or town where institution resides. Has the predicate function I

=item * B

Has the predicate function I

=item * B

Has the predicate function I

=item * B

Has the predicate function I. The email address for the instition including a I prefix. A scalar if there ist just one email address, an array reference if there are more than one adresses (in this case C is set to I<1>

=item * B

set to I<1> if there is more than one address in C

=item * B

The longitude of the place. Has the predicate function I.

=item * B

The latitude of the place. Has the predicate function I

=item * B

I or I

=item * B

error message, if C<$self->status> is I

=back

=head1 DEPENDENCIES

L, L, L, L, L

=head1 LOGGING

This module uses the L Framework

=head1 AUTHOR

Peter Mayr

=head1 REPOSITORY

The source code is also on GitHub . Pull requests and bug reports welcome!

=head1 VERSION

0.005

=head1 LICENCE AND COPYRIGHT

GNU GPL V3

Peter Mayr 2016

=cut

use strict;
use warnings;

use HTTP::Tiny;
use JSON;
use Log::Any;
use Moo;
use Try::Tiny;

extends 'WebService::Lobid';

has isil => ( is => 'rw', predicate => 1, required => 1 );
has name => ( is => 'rw', predicate => 1 );
has url  => ( is => 'rw', predicate => 1 );
has provides  => ( is => 'rw', predicate => 1 );
has addressCountry         => ( is => 'rw', predicate => 1 );
has addressLocality            => ( is => 'rw', predicate => 1 );
has postalCode          => ( is => 'rw', predicate => 1 );
has streetAddress       => ( is => 'rw', predicate => 1 );
has email               => ( is => 'rw', predicate => 1 );
has has_multiple_emails => ( is => 'rw', default   => 0 );
has lon                 => ( is => 'rw', predicate => 1 );
has lat                 => ( is => 'rw', predicate => 1 );
has found               => ( is => 'rw', default   => 'false' );

has log => (
    is      => 'ro',
    default => sub { Log::Any->get_logger },
);

sub BUILD {
    my $self = shift;

    my $query_string  = undef;
    my $response      = undef;
    my $json_result   = undef;
    my $result_ref    = undef;
    my $no_of_results = undef;
    my %data          = ();
    my $email         = undef;
    my $uri = sprintf( "%s%s/%s", $self->api_url, "organisation", $self->isil );

    $query_string = sprintf( "%s%s/%s.json",
                             $self->api_url, "organisations", $self->isil );

    $self->log->infof( "URL: %s", $query_string );
    $response = HTTP::Tiny->new(timeout => $self->api_timeout)->get($query_string);

    if ( $response->{success} ) {
        $json_result = $response->{content};
    }
    else {

        if ( $response->{status} eq '404' ) {
            $self->log->warnf( "ISIL %s not found!", $self->isil );
            $self->status('OK');
            $self->found("false");
            return;
        }
        else {
            $self->log->errorf( "Problem accessing the API: %s!",
                                $response->{status} );
            $self->status("Error");
            $self->error(sprintf("Problem accessing the API: %s!",
                                $response->{status}));
            return;
        }
    }

    $self->log->debugf( "Got JSON Result: %s", $json_result );

    try {
        $result_ref = decode_json($json_result);
    }
    catch {
        $self->log->errorf( "Decoding of response '%s' failed: %s",
                            $json_result, $_ );
        $self->status("Error");
        $self->error(sprintf("Decoding of response '%s' failed: %s",
                             $json_result, $_)
                    );
        return;
    };

    if ( $result_ref->{isil} eq $self->isil ) {
        $self->log->infof( "Got result for ISIL %s", $self->isil );
        $self->found("true");
        $self->status("OK");
    }

    if ( $result_ref->{email} ) {
        $email = $result_ref->{email};
        if ( ref($email) eq 'ARRAY' ) {    # multiple E-Mail Adresses
            $self->has_multiple_emails(1);
            for ( my $i = 0; $i < scalar( @{$email} ); $i++ ) {
                $email->[$i] =~ s/^mailto://;
            }
        }
        else {

            $email =~ s/^mailto://;

        }
        $self->email($email);
    }

    $self->name( $result_ref->{name} ) if ( $result_ref->{name} );
    $self->url( $result_ref->{url} )   if ( $result_ref->{url} );
    $self->provides( $result_ref->{provides} )   if ( $result_ref->{provides} );

    if (    ( defined( $result_ref->{location} ) )
         && ( ref( $result_ref->{location} ) eq 'ARRAY' ) )
    {
        if ( $result_ref->{location}->[0]->{geo} ) {
            $self->lat( $result_ref->{location}->[0]->{geo}->{lat} );
            $self->lon( $result_ref->{location}->[0]->{geo}->{lon} );
        }
        if ( $result_ref->{location}->[0]->{address} ) {
            $self->addressCountry(
                    $result_ref->{location}->[0]->{address}->{addressCountry} );
            $self->addressLocality(
                   $result_ref->{location}->[0]->{address}->{addressLocality} );
            $self->postalCode(
                        $result_ref->{location}->[0]->{address}->{postalCode} );
            $self->streetAddress(
                     $result_ref->{location}->[0]->{address}->{streetAddress} );

        }
    }

} ## end sub BUILD

1;