File Coverage

blib/lib/WebService/Lob.pm

Criterion	Covered	Total	%
statement	12	26	46.1
branch	0	10	0.0
condition			n/a
subroutine	4	7	57.1
pod			n/a
total	16	43	37.2

package WebService::Lob;
$WebService::Lob::VERSION = '0.0105';
use Moo;
with 'WebService::BaseClientRole';

# VERSION

use aliased 'WebService::Lob::Exception::AddressNotFound';
use aliased 'WebService::Lob::Exception::AddressMissingInformation';

use Function::Parameters ':strict';

has '+base_url'   => ( default => 'https://api.lob.com/v1' );
has api_key       => ( is => 'ro', required => 1           );
has states_uri    => ( is => 'ro', default => '/states'    );
has countries_uri => ( is => 'ro', default => '/countries' );
has verify_uri    => ( is => 'ro', default => '/verify'    );

method BUILD {
    $self->ua->credentials('api.lob.com:443', '', $self->api_key, '');
}

method get_states {
    my $result = $self->get($self->states_uri);
    return $result->{data} if $result;
}

method get_countries {
    my $result = $self->get($self->countries_uri);
    return $result->{data} if $result;
}

method verify_address(
    Str :$address_line1,
    Str :$address_line2 = '',
    Str :$address_city,
    Str :$address_state,
    Str :$address_zip,
    Str :$address_country
) {
    my $result = $self->post($self->verify_uri, {
        address_line1   => $address_line1,
        address_line2   => $address_line2,
        address_city    => $address_city,
        address_state   => $address_state,
        address_zip     => $address_zip,
        address_country => $address_country,
    });

    AddressNotFound->throw unless $result;
    AddressMissingInformation->throw( message => $result->{message} )
        if $result->{message};
    return $result->{address};
}


1;

__END__