File Coverage

blib/lib/WebService/Geocodio/Location.pm

Criterion	Covered	Total	%
statement	50	57	87.7
branch	21	30	70.0
condition	9	18	50.0
subroutine	8	9	88.8
pod	0	1	0.0
total	88	115	76.5

use strict;
use warnings;

package WebService::Geocodio::Location;
$WebService::Geocodio::Location::VERSION = '0.05';
use WebService::Geocodio::Fields;
use Moo;
use strictures 2;
use Carp qw(confess);

# ABSTRACT: Location object for use with Geocod.io service.


has [qw(number street suffix postdirection city state zip formatted lat lng accuracy fields)] => (
    is => 'ro',
    predicate => 1,
);


sub BUILDARGS {
    my ( $class, @args ) = @_;

    my $out;
    if (ref($args[0]) eq "HASH") {
        my $hr = $args[0];
        $out->{accuracy} = $hr->{accuracy} if exists $hr->{accuracy};
        $out->{formatted} = $hr->{formatted_address} if exists $hr->{formatted_address};
        $out->{fields} = WebService::Geocodio::Fields->new($hr->{fields}) if exists $hr->{fields};
        map { $out->{$_} = $hr->{address_components}->{$_} if exists $hr->{address_components}->{$_} } qw(number street suffix postdirection city state zip);
        map { $out->{$_} = $hr->{location}->{$_} if exists $hr->{location}->{$_} } qw(lat lng);
    }
    elsif ( @args % 2 == 1 ) {
        $out->{formatted} = $args[0];
    }
    else {
        $out = { @args };
    }

    return $out;
}

sub _forward_formatting {
    my $self = shift;

    return $self->formatted if $self->has_formatted;

    if ( ( not $self->has_zip ) && ( not ( $self->has_city && $self->has_state ) ) ) {
        confess "A zip or city-state pair is required.\n";
    }

    my $s;
    if ( $self->has_number && $self->has_street && $self->suffix ) {
        my @f;
        if ( $self->has_postdirection ) {
            @f = qw(number postdirection street suffix);
        }
        else {
            @f = qw(number street suffix);
        }

        $s .= join " ", (map {; $self->$_ } @f);
        $s .= ", ";
    }

    if ( $self->has_city && $self->has_state) {
        $s .= join ", ", (map {; $self->$_ } qw(city state));
        $s .= " " if ( $self->has_zip );
    }

    if ( $self->has_zip ) {
        $s .= $self->zip
    }

    return $s;
}

sub _reverse_formatting {
    my $self = shift;

    if ( not ( $self->has_lat && $self->has_lng ) ) {
        confess "lat-lng pair is required\n";
    }

    return join ",", ( map {; $self->$_ } qw(lat lng) );
}


1;

__END__