File Coverage

blib/lib/WWW/Slides.pm

Criterion	Covered	Total	%
statement	18	58	31.0
branch	0	26	0.0
condition	0	8	0.0
subroutine	6	8	75.0
pod	1	1	100.0
total	25	101	24.7

package WWW::Slides;

use version; our $VERSION = qv('0.0.8');

use warnings;
use strict;
use Carp;
use base 'Exporter';
use Scalar::Util qw( blessed );

our @EXPORT    = qw();
our @EXPORT_OK = qw( spawn_server );

# Module implementation here

sub _launch_server {
   my %config = %{$_[0]};

   # Prepare and run
   if (!exists $config{talk}) {
      if (blessed $config{slides}) {
         $config{slide_show} = $config{slides};
      }
      else {
         require WWW::Slides::SlideShow;
         $config{slide_show} = WWW::Slides::SlideShow->new();
         $config{slide_show}->read($config{slides});
      }

      if (!exists $config{controller}) {
         require WWW::Slides::Controller::TCP;
         $config{controller} =
           WWW::Slides::Controller::TCP->new(
            port => $config{'controller_port'},);
      } ## end if (!exists $config{controller...

      if ($config{debug} && !exists $config{logger}) {
         require WWW::Slides::BasicLogger;
         $config{logger} =
           WWW::Slides::BasicLogger->new(channel => \*STDERR);
      }

      # Ensure a couple of defaults
      $config{accepts_detaches} = 1
        unless exists $config{accepts_detaches};
      $config{ping_interval} ||= 10;
      $config{port} = $config{http_port};

      require WWW::Slides::Talk;
      $config{talk} = WWW::Slides::Talk->new(%config);
   } ## end if (!exists $config{talk...

   # Daemonise
   require POSIX;
   POSIX::setsid();    # not a must IMHO: or die "setsid: $!";
   chdir '/';
   close STDOUT;
   close STDERR unless $config{debug};
   close STDIN;
   $SIG{PIPE} = 'IGNORE';    # For stray connections

   # Run talk
   $config{talk}->run();

   exit 0;
} ## end sub _launch_server

sub spawn_server {
   my ($config_href) = @_;
   croak "expected HASH ref as input parameter"
     unless ref($config_href) eq 'HASH';
   my %config = %$config_href;

   # First, let's see if we have all we need, which is little
   if (!exists $config{talk}) {
      croak "nowhere to take the slides from, provide a 'slides' parameter"
        unless exists $config{slides};

      croak "please provide either a 'controller' or a 'controller_port'"
        unless exists($config{controller})
        || exists($config{controller_port});

      croak "please provide an 'http_port' to listen to"
        unless $config{http_port};
   } ## end if (!exists $config{talk...

   # Here the iato comes
   my $pid = fork();
   die "could not fork(): $!"  unless defined $pid;    # error
   _launch_server($config_href) unless $pid;            # child
   sleep(1);                                           # father
   return $pid;
} ## end sub spawn_server

1;    # Magic true value required at end of module
__END__