File Coverage

blib/lib/Vim/Complete.pm

Criterion	Covered	Total	%
statement	53	60	88.3
branch	9	22	40.9
condition	3	5	60.0
subroutine	11	12	91.6
pod	4	4	100.0
total	80	103	77.6

use 5.008;
use strict;
use warnings;

package Vim::Complete;
our $VERSION = '1.100880';
# ABSTRACT: Generate auto completion information for vim
use PPI;
use File::Find;
use File::Spec;
use parent qw(Class::Accessor::Complex);
__PACKAGE__->mk_new->mk_scalar_accessors(qw(min_length))
  ->mk_array_accessors(qw(dirs))->mk_hash_accessors(qw(result))
  ->mk_boolean_accessors(qw(verbose));

sub gather {
    my ($self, $filename) = @_;

    # does PPI not like relative filenames?
    $filename = File::Spec->rel2abs($filename);
    my $document = PPI::Document->new($filename);
    unless (UNIVERSAL::isa($document, 'PPI::Document')) {
        warn "couldn't parse $filename\n";
        return;
    }

    # get a hash reference so we can change the hash in place
    my $result = $self->result;
    my $min_length = $self->min_length || 3;
    $result->{$_} = 1
      for grep { /\w{$min_length,}/ }
      map      { $_->namespace }
      @{ $document->find('PPI::Statement::Package') || [] };
    $result->{$_} = 1
      for grep { /\w{$min_length,}/ }
      map { substr($_, 0, 1, ''); $_ }
      map { $_->variables }
      @{ $document->find('PPI::Statement::Variable') || [] };
    $result->{$_} = 1
      for grep { /\w{$min_length,}/ }
      map { $_->name } @{ $document->find('PPI::Statement::Sub') || [] };
}

sub report {
    my $self   = shift;
    my @result = sort $self->result_keys;
    wantarray ? @result : \@result;
}

sub report_to_file {
    my ($self, $filename) = @_;
    die "no filename\n" unless defined $filename;
    open my $fh, '>', $filename or die "can't open $filename for writing: $!\n";
    print $fh "$_\n" for $self->report;
    close $fh or die "can't close $fh: $!\n";
}

sub parse {
    my $self    = shift;
    my $verbose = $self->verbose;
    find(
        sub {
            return unless -f && /\.pm$/;

          # We can see a file more than once if we have nested paths in @INC, so
          # check
            our %seen;
            return if $seen{$File::Find::name}++;
            warn "processing $File::Find::name\n" if $verbose;
            $self->gather($_);
        },
        $self->dirs
    );
    $self;    # for chaining
}
1;


__END__