File Coverage

blib/lib/Time/Duration/Object/Infinite.pm

Criterion	Covered	Total	%
statement	35	42	83.3
branch	6	8	75.0
condition			n/a
subroutine	16	22	72.7
pod	12	14	85.7
total	69	86	80.2

use strict;
use warnings;
package Time::Duration::Object::Infinite 0.302;
# ABSTRACT: Time::Duration::Object, but infinite

sub isa {
  return 1 if $_[1] eq 'Time::Duration::Object';
  return $_[0]->UNIVERSAL::isa($_[1]);
}

#pod =head1 SYNOPSIS
#pod
#pod  use Time::Duration::Object::Infinite;
#pod
#pod  my $duration = Time::Duration::Object::Infinite->new_future;
#pod
#pod  # It will happen forever from now.
#pod  print "It will happen ", $duration->from_now;
#pod
#pod =head1 DESCRIPTION
#pod
#pod This is a class for Time::Duration::Object-like objects representing infinite
#pod durations.
#pod
#pod =method new
#pod
#pod =method new_positive
#pod
#pod These methods return a new Time::Duration::Object::Infinite for a positive
#pod duration.
#pod
#pod =cut

sub new_positive {
	my ($class) = @_;
  my $duration = 1;
	bless \$duration => $class;
}

sub new { shift->new_positive }

#pod =method new_negative
#pod
#pod This returns a new Time::Duration::Object::Infinite for a negative duration.
#pod
#pod =cut

sub new_negative {
	my ($class) = @_;
  my $duration = -1;
	bless \$duration => $class;
}

sub _is_pos { ${$_[0]} == -1 }

#pod =method new_seconds
#pod
#pod This method returns either C<+inf> or C<-inf> using Math::BigInt.  (I don't
#pod recommend calling it.)
#pod
#pod =cut

sub seconds {
  require Math::BigInt;
  return Math::BigInt->binf(shift->_is_pos ? '-' : ());
}

#pod =method duration
#pod
#pod =method duration_exact
#pod
#pod These methods both return "forever."
#pod
#pod =cut

sub duration { 'forever' }

# This is to make it easy to implement the matched pair methods.
sub _flop {
  my ($self, $flop, $pair) = @_;
  my $is_pos = $flop ? ! $self->_is_pos : $self->_is_pos;
  my $index = $is_pos ? 0 : 1;
  my $str = $pair->[$index];
  bless \$str => 'Time::Duration::_Result::_Infinite';
}

my $ago_from_now;
my $earlier_later;
BEGIN {
  $ago_from_now  = [ 'forever ago', 'forever from now' ];
  $earlier_later = [ 'infinitely earlier', 'infinitely later' ];
}

#pod =method ago
#pod
#pod =method ago_exact
#pod
#pod These methods return "forever ago" for positive durations and "forever from
#pod now" for negative durations.
#pod
#pod =cut

sub ago       { $_[0]->_flop(1, $ago_from_now); }
sub ago_exact { $_[0]->_flop(1, $ago_from_now); }

#pod =method from_now
#pod
#pod =method from_now_exact
#pod
#pod These methods do the opposite of the C methods.
#pod
#pod =cut

sub from_now       { $_[0]->_flop(0, $ago_from_now); }
sub from_now_exact { $_[0]->_flop(0, $ago_from_now); }

#pod =method later
#pod
#pod =method later_exact
#pod
#pod These methods return "infinitely later" for positive durations and "infinitely
#pod earlier" for negative durations.
#pod
#pod =cut

sub later       { $_[0]->_flop(0, $earlier_later); }
sub later_exact { $_[0]->_flop(0, $earlier_later); }

#pod =method earlier
#pod
#pod =method earlier_exact
#pod
#pod These methods do the opposite of the C methods.
#pod
#pod =cut

sub earlier       { $_[0]->_flop(1, $earlier_later); }
sub earlier_exact { $_[0]->_flop(1, $earlier_later); }

package Time::Duration::_Result::_Infinite 0.302;

#pod =method concise
#pod
#pod This method can be called on the result of the above methods, trimming down the
#pod ouput.  For example:
#pod
#pod  my $duration = Time::Duration::Object::Infinite->new_positive;
#pod  print $duration->ago; # forever ago
#pod  print $duration->ago->concise # forever ago
#pod
#pod Doesn't look any shorter, does it?  No, it won't be.  These methods are here
#pod for compatibility with Time::Duration::Object's returns.
#pod
#pod =cut

sub concise {
	${ $_[0] }
}

sub as_string { ${ $_[0] } }

use overload
	'""' => 'as_string',
	fallback => 1;

1;

__END__