File Coverage

blib/lib/Text/Sass/XS.pm

Criterion	Covered	Total	%
statement	18	76	23.6
branch	0	26	0.0
condition	0	3	0.0
subroutine	6	18	33.3
pod			n/a
total	24	123	19.5

package Text::Sass::XS;
use 5.008005;
use strict;
use warnings;
use base 'Exporter';
use Carp ();

our $VERSION = "0.11";

my @constants = qw(
    SASS_STYLE_NESTED
    SASS_STYLE_EXPANDED
    SASS_STYLE_COMPRESSED
    SASS_SOURCE_COMMENTS_NONE
    SASS_SOURCE_COMMENTS_DEFAULT
    SASS_SOURCE_COMMENTS_MAP
);
my @functions = qw(
    sass_compile
    sass_compile_file
);
our @EXPORT_OK = ( @constants, @functions );
our %EXPORT_TAGS = (
    'all'   => [ @constants, @functions ],
    'const' => \@constants,
    'func'  => \@functions
);

use XSLoader;
XSLoader::load( __PACKAGE__, $VERSION );

sub sass_compile {
    my $source_string = shift;

    my $result;
    if (@_) {
        $result = _compile( $source_string, +{ _normalize_options(@_) } );
    }
    else {
        $result = _compile($source_string);
    }

    wantarray
        ? ( $result->{output_string}, $result->{error_message} )
        : $result->{output_string};
}

sub sass_compile_file {
    my $input_path = shift;

    my $result;
    if (@_) {
        $result = _compile_file( $input_path, +{ _normalize_options(@_) } );
    }
    else {
        $result = _compile_file($input_path);
    }

    wantarray
        ? ( $result->{output_string}, $result->{error_message} )
        : $result->{output_string};
}

sub _normalize_options {
    return unless @_;

    my %options = ref $_[0] eq 'HASH' ? %{ $_[0] } : @_;

    # include_paths must be a colon separated string.
    if ( $options{include_paths}
        && ref $options{include_paths} eq 'ARRAY' )
    {
        $options{include_paths} = join ':', @{ $options{include_paths} };
    }
    else {
        $options{include_paths} = "";
    }

    $options{image_path} = "" unless $options{image_path};

    return %options;
}

# OO Interface
sub new {
    my $class = shift;

    my $self = bless {
        options => {
            output_style    => SASS_STYLE_COMPRESSED(),
            source_comments => SASS_SOURCE_COMMENTS_NONE(),
            include_paths   => undef,
            image_path      => undef,
            @_,
        },
        _errstr => undef,
    }, $class;

    return $self;
}

sub options {
    my $self = shift;
    $self->{options};
}

sub errstr {
    my $self = shift;
    if (@_) {
        $self->{_errstr} = shift;
    }
    else {
        $self->{_errstr};
    }
}

sub compile {
    my $self          = shift;
    my $source_string = shift;

    my %options = _normalize_options( %{ $self->options } );
    my $result = _compile( $source_string, \%options );

    if ( $result->{error_status} ) {
        Carp::croak $result->{error_message};
    }
    else {
        return $result->{output_string};
    }
}

sub compile_file {
    my $self       = shift;
    my $input_path = shift;

    my %options = _normalize_options( %{ $self->options } );
    my $result = _compile_file( $input_path, \%options );

    if ( $result->{error_status} ) {
        Carp::croak $result->{error_message};
    }
    else {
        return $result->{output_string};
    }
}

# For Text::Sass Compatibility
sub scss2css { shift->compile(@_) }

sub sass2css {
    my $self = shift;
    $self->_require_pp;
    Text::Sass->new->sass2css(@_);
}

sub css2sass {
    my $self = shift;
    $self->_require_pp;
    Text::Sass->new->css2sass(@_);
}

sub _require_pp {
    return if $INC{"Text/Sass.pm"};
    local $@;
    eval 'require Text::Sass;';
    if ($@) {
        Carp::croak
            "Cannot load Text::Sass. If you want to use css2sass or sass2css method, you need to install Text::Sass first.";
    }
}

1;
__END__