File Coverage

blib/lib/Text/Hyphen/GenderInclusive.pm

Criterion	Covered	Total	%
statement	32	34	94.1
branch	8	12	66.6
condition	3	9	33.3
subroutine	5	5	100.0
pod	0	2	0.0
total	48	62	77.4

package Text::Hyphen::GenderInclusive;
use strict;
use warnings;
use Carp;

our $VERSION = '1.00';

sub new {
    my ( $class, %args ) = @_;
    $class = ref $class || $class;
    my $base_class = delete $args{class};
    if ( !$base_class ) {
        croak "Missing class argument.";
    }
    eval "require $base_class" or croak $@;
    my $self;
    $self->{re} ||= delete( $args{re} ) || qr/[:*_]/;
    $self->{hyphenator} = $base_class->new(%args);
    bless $self, $class;
}

sub hyphenate {
    my ( $self, $word, $delim ) = @_;
    my $re = $self->{re};
    $word =~ s/(?<=\w)($re)(?=\w)//;
    my $char  = $1;
    my $pos   = $-[0];
    my @parts = $self->{hyphenator}->hyphenate($word);
    if ($char) {
        for my $part (@parts) {
            if ( length($part) < $pos ) {
                $pos -= length($part);
            }
            else {
                substr( $part, $pos, 0 ) = $char;
                last;
            }
        }
    }
    if ( defined($delim) ) {
        return join( $delim, @parts );
    }
    else {
        return wantarray ? @parts : join( '-', @parts );
    }
}

1;

__END__