File Coverage

blib/lib/Text/CountString.pm

Criterion	Covered	Total	%
statement	31	31	100.0
branch	12	12	100.0
condition	14	15	93.3
subroutine	8	8	100.0
pod	1	1	100.0
total	66	67	98.5

package Text::CountString;
use strict;
use warnings;
use utf8;

our $VERSION = '0.03';

my $COUNTER;

sub import {
    my ($class, $implement) = @_;

    $COUNTER = ($implement && $implement eq 'split')
             ? \&_split_implement
             : \&_regexp_implement;

    my $caller = caller;
    no strict 'refs'; ## no critic
    *{"${caller}::count_string"} = \&count_string;
}

sub _regexp_implement {
    return 0 if !defined($_[0]) || $_[0] eq '';
    return 0 if !defined($_[1]) || $_[1] eq '';
    return () = ($_[0] =~ /\Q$_[1]\E/g);
}

sub _split_implement {
    return 0 if !defined($_[0]) || $_[0] eq '';
    return 0 if !defined($_[1]) || $_[1] eq '';
    my @list = split /\Q$_[1]\E/, $_[0], -1;
    return scalar(@list) - 1;
}

sub count_string {
    my $target_text = shift;

    my $result;

    if (@_ == 1) {
        $result = $COUNTER->($target_text, $_[0]);
    }
    else {
        for my $string (@_) {
            $result->{$string} = $COUNTER->($target_text, $string);
        }
    }
    return $result;
}

1;

__END__