File Coverage

blib/lib/Test/Tiny.pm

Criterion	Covered	Total	%
statement	24	26	92.3
branch	11	12	91.6
condition	1	2	50.0
subroutine	6	7	85.7
pod	5	5	100.0
total	47	52	90.3

package Test::Tiny;

=head1 NAME

Test::Tiny -- Write simple tests, simply.

=head1 SYNOPSIS

    use Test::Tiny tests => NUMBER;
    ok(TEST [, MESSAGE]);    # pass if TEST is true, and print MESSAGE
    show(TEST);              # pass if eval(TEST) is true, print TEST
    SKIP: {
        skip(MESSAGE, N);
        # skip this code, including N tests
    }
    BAIL_OUT([MESSAGE]);        # give up, printing MESSAGE.

=cut

$VERSION = '0.02';

sub import
{
    my $caller = caller;
    *{"$caller\::$_"} = \&$_ for qw(ok show skip BAIL_OUT done_testing);
    $PLAN = @_ == 3 ? 0+$_[2] : -1;
    print "1..", $PLAN < 0 ? 0 : $PLAN, "\n";
}

sub ok
{
    my $res = shift;
    if ($res) {
        ++$SUCC;
    } else {
        print "not ";
        ++$FAIL;
    }
    (my $desc = shift || '') =~ s/\n/\n# /g;
    print "ok ", $SUCC + $FAIL, ($desc ? " - $desc" : ""), "\n";
    if (!$res) {
        my ($pack, $file, $line, $i);
        ($pack, $file, $line) = caller(++$i) while $pack eq 'Test::Tiny';
        print "# Failed at $file line $line\n";
    }
}

sub show
{
    my $test = shift;
    ok(eval($test), $test);
}

sub skip
{
    my ($why, $n) = @_;
    ok(1, "skipped -- $why") while $n-- > 0;
    last SKIP;
}

sub BAIL_OUT
{
    print "Bail out!", @_, "\n";
    exit 255;
}

sub done_testing
{
    undef $EXIT;
    exit $FAIL;
}

$EXIT = sub {
    exit($FAIL || abs($PLAN-$SUCC));
};

END { $EXIT->() if $EXIT; }

1;
__END__