File Coverage

blib/lib/Test/Stream/Event/Plan.pm

Criterion	Covered	Total	%
statement	48	48	100.0
branch	26	26	100.0
condition	8	9	88.8
subroutine	11	11	100.0
pod	4	5	80.0
total	97	99	97.9

package Test::Stream::Event::Plan;
use strict;
use warnings;

use base 'Test::Stream::Event';
use Test::Stream::HashBase accessors => [qw/max directive reason/];

use Test::Stream::Formatter::TAP qw/OUT_STD/;
use Carp qw/confess/;

my %ALLOWED = (
    'SKIP'    => 1,
    'NO PLAN' => 1,
);

sub init {
    $_[0]->SUPER::init();

    if ($_[0]->{+DIRECTIVE}) {
        $_[0]->{+DIRECTIVE} = 'SKIP'    if $_[0]->{+DIRECTIVE} eq 'skip_all';
        $_[0]->{+DIRECTIVE} = 'NO PLAN' if $_[0]->{+DIRECTIVE} eq 'no_plan';

        confess "'" . $_[0]->{+DIRECTIVE} . "' is not a valid plan directive"
            unless $ALLOWED{$_[0]->{+DIRECTIVE}};
    }
    else {
        confess "Cannot have a reason without a directive!"
            if defined $_[0]->{+REASON};

        confess "No number of tests specified"
            unless defined $_[0]->{+MAX};

        confess "Plan test count '" . $_[0]->{+MAX}  . "' does not appear to be a valid positive integer"
            unless $_[0]->{+MAX} =~ m/^\d+$/;

        $_[0]->{+DIRECTIVE} = '';
    }
}

sub to_tap {
    my $self = shift;

    my $max       = $self->{+MAX};
    my $directive = $self->{+DIRECTIVE};
    my $reason    = $self->{+REASON};

    return if $directive && $directive eq 'NO PLAN';

    my $plan = "1..$max";
    if ($directive) {
        $plan .= " # $directive";
        $plan .= " $reason" if defined $reason;
    }

    return [OUT_STD, "$plan\n"];
}

sub update_state {
    my $self = shift;
    my ($state) = @_;

    $state->plan($self->{+DIRECTIVE} || $self->{+MAX});
    $state->set_skip_reason($self->{+REASON});
}

sub terminate {
    my $self = shift;
    # On skip_all we want to terminate the hub
    return 0 if $self->{+DIRECTIVE} && $self->{+DIRECTIVE} eq 'SKIP';
    return undef;
}

sub global {
    my $self = shift;
    return 0 unless $self->{+DIRECTIVE};
    return 0 unless $self->{+DIRECTIVE} eq 'SKIP';
    return 1;
}

1;

__END__