File Coverage

blib/lib/Term/Vspark.pm

Criterion	Covered	Total	%
statement	64	70	91.4
branch	17	28	60.7
condition	7	12	58.3
subroutine	11	11	100.0
pod	1	2	50.0
total	100	123	81.3

package Term::Vspark;

use strict;
use warnings;
use Carp qw{ croak };
use utf8;

use Exporter::Shiny qw/show_graph/;

our $VERSION = 0.32;

sub _bar {
    my (%args) = @_;

    my $value   = $args{value};
    my $max     = $args{max};
    my $columns = $args{columns};
    my $char    = $args{char};

    my @char_list = $char
        ? ($char)
        : (qw{ ▏ ▎ ▍ ▌ ▋ ▊ ▉ █});

    # calculate the length of the bar
    my $length = $value * $columns / $max; # length of the bar
    $length = $columns if $length > $columns;

    # empty $bar
    my $bar = '';

    # build integer portion of the bar
    my $integer = int $length;
    $bar .= $char_list[-1] x $integer;

    # build decimal portion of the bar
    my $decimal = $length - $integer;
    if ($decimal > 0) {
        my $index = int scalar @char_list * $decimal;
        $bar .= $char_list[$index];
    }

    return $bar;
}

sub vspark {
    my %args = @_;

    croak 'values is not an ArrayRef'
        if ref $args{'values'} ne 'ARRAY';

    croak 'labels is not an ArrayRef'
        if $args{'labels'} && ref $args{'labels'} ne 'ARRAY';

    my $max     = $args{max};
    my $columns = _term_width($args{columns});
    my @labels  = @{ $args{labels} || [] };
    my @values  = @{ $args{values} };
    my $char    = $args{char};

    croak 'the number of labels and values must be equal'
        if $args{labels} && scalar @labels != scalar @values;

    $max          //= _max_value(@values);
    my $label_width = _max_label_width(@labels);
    my $bar_width   = $columns - $label_width;
    my $graph       = q{};

    for my $value (@values) {
        my $label = shift @labels;
        my $bar   = _bar(
            value   => $value,
            max     => $max,
            columns => $bar_width,
            char    => $char,
        );

        $graph .= sprintf("%${label_width}s", " $label ") if defined $label;
        $graph .= $bar . "\n";
    }

    return $graph;
}

# for backwards compatibility
sub show_graph { vspark(@_) }

sub _term_width {
    my $columns = shift;
    return $columns if $columns && $columns ne 'max';

    require Term::ReadKey;
    my ($cols) = Term::ReadKey::GetTerminalSize(*STDOUT);
    return 80    if !$cols;
    return $cols if  $columns eq 'max';
    return 80    if $cols > 80;
    return $cols;
}

sub _max_value {
    my @values = @_;
    my @sorted = sort @values;
    return 0 unless @sorted;
    return $sorted[-1];
}

sub _max_label_width {
    my @labels = @_;

    return 0 if scalar @labels == 0;

    my @lengths = sort map { length $_ } @labels;
    return $lengths[-1] + 2; # + 2 because of 1 space before and after label
}

1;
__END__