File Coverage

blib/lib/Tags/HTML/Table/View.pm

Criterion	Covered	Total	%
statement	79	88	89.7
branch	11	20	55.0
condition	4	6	66.6
subroutine	13	14	92.8
pod	1	1	100.0
total	108	129	83.7

package Tags::HTML::Table::View;

use base qw(Tags::HTML);
use strict;
use warnings;

use Class::Utils qw(set_params split_params);
use Error::Pure qw(err);
use List::MoreUtils qw(none);
use Scalar::Util qw(blessed);

our $VERSION = 0.03;

# Constructor.
sub new {
	my ($class, @params) = @_;

	# Create object.
	my ($object_params_ar, $other_params_ar) = split_params(
		['css_table', 'header'], @params);
	my $self = $class->SUPER::new(@{$other_params_ar});

	# Main CSS class.
	$self->{'css_table'} = 'table';

	# Header is in first line.
	$self->{'header'} = 1;

	# Process params.
	set_params($self, @{$object_params_ar});

	# Object.
	return $self;
}

sub _cleanup {
	my $self = shift;

	delete $self->{'_data'};
	delete $self->{'_no_data'};

	return;
}

sub _init {
	my ($self, $data_ar, $no_data_value) = @_;

	$self->{'_data'} = $data_ar;
	$self->{'_no_data'} = $no_data_value;

	return;
}

# Process 'Tags'.
sub _process {
	my $self = shift;

	if (! exists $self->{'_data'}) {
		return;
	}

	# Main content.
	$self->{'tags'}->put(
		['b', 'table'],
		['a', 'class', $self->{'css_table'}],
	);
	my $columns_count = 0;
	if ($self->{'header'}) {
		$self->{'tags'}->put(
			['b', 'tr'],
		);
		my $header_ar = shift @{$self->{'_data'}};
		foreach my $value (@{$header_ar}) {
			$self->{'tags'}->put(
				['b', 'th'],
				['d', $value],
				['e', 'th'],
			);
			$columns_count++;
		}
		$self->{'tags'}->put(
			['e', 'tr'],
		);
	} else {
		$columns_count++;
	}
	foreach my $row_ar (@{$self->{'_data'}}) {
		$self->{'tags'}->put(
			['b', 'tr'],
		);
		foreach my $value (@{$row_ar}) {
			$self->{'tags'}->put(
				['b', 'td'],
			);
			$self->_value($value);
			$self->{'tags'}->put(
				['e', 'td'],
			);
		}
		$self->{'tags'}->put(
			['e', 'tr'],
		);
	}

	# No data row.
	if (! @{$self->{'_data'}} && defined $self->{'_no_data'}) {
		$self->{'tags'}->put(
			['b', 'tr'],
			['b', 'td'],
			['a', 'colspan', $columns_count],
		);
		$self->_value($self->{'_no_data'});
		$self->{'tags'}->put(
			['e', 'td'],
			['e', 'tr'],
		);
	}

	$self->{'tags'}->put(
		['e', 'table'],
	);

	return;
}

# Process 'CSS::Struct'.
sub _process_css {
	my $self = shift;

	$self->{'css'}->put(
		['s', '.'.$self->{'css_table'}],
		['s', '.'.$self->{'css_table'}.' td'],
		['s', '.'.$self->{'css_table'}.' th'],
		['d', 'border', '1px solid #ddd'],
		['d', 'text-align', 'left'],
		['e'],

		['s', '.'.$self->{'css_table'}],
		['d', 'border-collapse', 'collapse'],
		['d', 'width', '100%'],
		['e'],

		['s', '.'.$self->{'css_table'}.' th'],
		['s', '.'.$self->{'css_table'}.' td'],
		['d', 'padding', '15px'],
		['e'],
	);

	return;
}

sub _tags_a {
	my ($self, $value) = @_;

	$self->{'tags'}->put(
		['b', 'a'],
		defined $value->css_class ? (
			['a', 'class', $value->css_class],
		) : (),
		defined $value->url ? (
			['a', 'href', $value->url],
		) : (),
	);
	if ($value->data_type eq 'plain') {
		$self->{'tags'}->put(
			['d', @{$value->data}],
		);
	} elsif ($value->data_type eq 'tags') {
		$self->{'tags'}->put($value->data);
	}
	$self->{'tags'}->put(
		['e', 'a'],
	);

	return;
}

sub _value {
	my ($self, $value) = @_;

	if (ref $value eq '') {
		$self->{'tags'}->put(
			['d', $value],
		);
	} elsif (ref $value eq 'ARRAY') {
		$self->{'tags'}->put(@{$value});
	} elsif (blessed($value) && $value->isa('Data::HTML::A')) {
		$self->_tags_a($value);
	} else {
		err 'Bad value object.';
	}

	return;
}

1;

__END__