File Coverage

blib/lib/Switch/Reftype.pm

Criterion	Covered	Total	%
statement	31	32	96.8
branch	3	4	75.0
condition	2	2	100.0
subroutine	16	17	94.1
pod	12	12	100.0
total	64	67	95.5

package Switch::Reftype;
$Switch::Reftype::VERSION = '0.001';
# ABSTRACT: Execute code based on which type of reference is given.
use strict;
use warnings;
use Scalar::Util 'reftype';

require Exporter;
our @ISA = qw(Exporter);
our %EXPORT_TAGS = ( 'all' => [ qw(
    switch_reftype
    if_SCALAR
    if_ARRAY
    if_HASH
    if_CODE
    if_REF
    if_GLOB
    if_LVALUE
    if_FORMAT
    if_IO
    if_VSTRING
    if_REGEXP
)]);
our @EXPORT_OK = map { @{$EXPORT_TAGS{$_}} } keys %EXPORT_TAGS;
our @EXPORT = qw(switch_reftype);


sub switch_reftype {
    my $ref = shift;
    my %dispatch = @_;
    my $reftype = defined($ref) && (reftype($ref) || "scalar") || "undef";
    for ($ref) {    # Alias $ref to $_
        for my $key ($reftype, 'default') {
            if (exists $dispatch{$key}) {
                my $result = $dispatch{$key};
                $result = $result->() if reftype $result eq "CODE";
                return $result;
            }
        }
    };
}


sub _if_reftype {
    my $ref = shift;
    switch_reftype $ref,
        @_,
        default => sub { $ref }
    ;
}

sub if_SCALAR (&$)  {   return _if_reftype($_[1], SCALAR    => $_[0]);  }
sub if_ARRAY (&$)   {   return _if_reftype($_[1], ARRAY     => $_[0]);  }
sub if_HASH (&$)    {   return _if_reftype($_[1], HASH      => $_[0]);  }
sub if_CODE (&$)    {   return _if_reftype($_[1], CODE      => $_[0]);  }
sub if_REF (&$)     {   return _if_reftype($_[1], REF       => $_[0]);  }
sub if_GLOB (&$)    {   return _if_reftype($_[1], GLOB      => $_[0]);  }
sub if_LVALUE (&$)  {   return _if_reftype($_[1], LVALUE    => $_[0]);  }
sub if_FORMAT (&$)  {   return _if_reftype($_[1], FORMAT    => $_[0]);  }
sub if_IO (&$)      {   return _if_reftype($_[1], IO        => $_[0]);  }
sub if_VSTRING (&$) {   return _if_reftype($_[1], VSTRING   => $_[0]);  }
sub if_REGEXP (&$)  {   return _if_reftype($_[1], REGEXP    => $_[0]);  }


1;

__END__