File Coverage

blib/lib/String/Trim.pm

Criterion	Covered	Total	%
statement	41	41	100.0
branch	31	34	91.1
condition			n/a
subroutine	4	4	100.0
pod	1	1	100.0
total	77	80	96.2

package String::Trim;
# ABSTRACT: trim whitespace from your strings
use strict;
use warnings;
our $VERSION = '0.005'; # VERSION


use Exporter 5.57 qw(import);
our @EXPORT = qw(trim);


sub trim { # Starting point: http://www.perlmonks.org/?node_id=36684
    my $t = qr{^\s+|\s+$};
    if (defined wantarray) {
        @_ = (@_ ? @_ : $_);
        if (ref $_[0] eq 'ARRAY') {
            @_ = @{ $_[0] };
            for (@_) { s{$t}{}g if defined $_ }
            return \@_;
        }
        elsif (ref $_[0] eq 'HASH') {
            foreach my $k (keys %{ $_[0] }) {
                (my $nk = $k) =~ s{$t}{}g;
                if (defined $_[0]->{$k}) {
                    ($_[0]->{$nk} = $_[0]->{$k}) =~ s{$t}{}g;
                }
                else {
                    $_[0]->{$nk} = undef;
                }
                delete $_[0]->{$k} unless $k eq $nk;
            }
        }
        else {
            for (@_ ? @_ : $_) { s{$t}{}g if defined $_ }
        }
        return wantarray ? @_ : $_[0];
    }
    else {
        if (ref $_[0] eq 'ARRAY') {
            for (@{ $_[0] }) { s{$t}{}g if defined $_ }
        }
        elsif (ref $_[0] eq 'HASH') {
            foreach my $k (keys %{ $_[0] }) {
                (my $nk = $k) =~ s{$t}{}g;
                if (defined $_[0]->{$k}) {
                    ($_[0]->{$nk} = $_[0]->{$k}) =~ s{$t}{}g;
                }
                else {
                    $_[0]->{$nk} = undef;
                }
                delete $_[0]->{$k} unless $k eq $nk
            }
        }
        else {
            for (@_ ? @_ : $_) { s{$t}{}g if defined $_ }
        }
    }
}


1;



=pod

=encoding utf-8

=head1 NAME

String::Trim - trim whitespace from your strings

=head1 VERSION

version 0.005

=head1 SYNOPSIS

    use String::Trim;

    print "Do it? ";
    trim(my $response = <>);
    print "'$response'\n";

=head1 DESCRIPTION

C trims whitespace off your strings. L trims only C<$/> (typically,
that's newline), but C will trim all leading and trailing whitespace.

=head1 FUNCTIONS

=head2 trim

Returns the string with all leading and trailing whitespace removed. Trimming
undef gives you undef. Alternatively, you can trim in-place.

    my $var     = ' my string  ';
    my $trimmed = trim($var);
    # OR
    trim($var);

C also knows how to trim an array or arrayref:

    my @to_trim = (' one ', ' two ', ' three ');
    my @trimmed = trim(@to_trim);
    # OR
    trim(@to_trim);
    # OR
    my $trimmed = trim(\@to_trim);
    # OR
    trim(\@to_trim);

=head1 RATIONALE

C is often used by beginners, who may not understand how to spin their own. While
L does have a C function, it depends on L, which
depends on L, which fails the test suite, and doesn't appear to be maintained.
This module installs, is actively maintained, and has no non-core dependencies.

Other options include L and L (which is implemented in XS,
and is therefore likely to be very fast, but requires a C compiler).

=head1 AVAILABILITY

The latest version of this module is available from the Comprehensive Perl
Archive Network (CPAN). Visit L to find a CPAN
site near you, or see L.

The development version lives at L
and may be cloned from L.
Instead of sending patches, please fork this project using the standard
git and github infrastructure.

=head1 SOURCE

The development version is on github at L
and may be cloned from L

=head1 BUGS AND LIMITATIONS

No bugs have been reported.

Please report any bugs or feature requests through the web interface at
L.

=head1 CREDITS

This module was inspired by code at L written
by japhy (Jeff Pinyan), dragonchild, and Aristotle. This Perl module was written by Mike
Doherty.

=head1 AUTHORS

=over 4

=item *

Mike Doherty

=item *

Jeff Pinyan

=item *

Rob Kinyon

=item *

Αριστοτέλης Παγκαλτζής (Aristotle Pagaltzis)

=back

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2010 by Mike Doherty.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut


__END__