File Coverage

blib/lib/SmokeRunner/Multi/Config.pm

Criterion	Covered	Total	%
statement	37	37	100.0
branch	6	6	100.0
condition	6	8	75.0
subroutine	16	16	100.0
pod	4	4	100.0
total	69	71	97.1

package SmokeRunner::Multi::Config;
BEGIN {
  $SmokeRunner::Multi::Config::AUTHORITY = 'cpan:YANICK';
}
{
  $SmokeRunner::Multi::Config::VERSION = '0.19';
}
#ABSTRACT: Config information for a Smokerunner::Multi setup

use strict;
use warnings;

use base 'Class::Singleton';

use File::Spec;
use File::HomeDir;
use YAML::Syck qw( LoadFile );

sub _new_instance
{
    my $class = shift;

    my $file = $class->_FindConfigFile();

    my $cfg = LoadFile($file);

    die "Config in $file for the smoke-runner was not valid.\n"
        unless $cfg && $cfg->{root};

    return bless $cfg, $class;
}

sub _FindConfigFile
{
    my $class = shift;

    my @files = (
        $class->_config_from_env,
        $class->_config_from_home,
        $class->_config_from_system,
    );

    for my $file (@files)
    {
        return $file if -f $file && -r _;
    }

    die "Cannot find a config file for the smoke-runner. Looked in [@files].\n";
}

sub _config_from_env {
    return $ENV{SMOKERUNNER_CONFIG} if $ENV{SMOKERUNNER_CONFIG};

    return;
}

sub _config_from_home {
    return File::Spec->catfile( File::HomeDir->my_home , '.smokerunner',
        'smokerunner.conf' );
}

sub _config_from_system { return '/etc/smokerunner/smokerunner.conf' }

sub root_dir { return $_[0]->{root} }
sub runner   { return $_[0]->{runner} }
sub reporter { return $_[0]->{reporter} }
sub smolder  { return $_[0]->{smolder} || {} }


1;

__END__