File Coverage

blib/lib/SQL/Easy.pm

Criterion	Covered	Total	%
statement	12	124	9.6
branch	0	40	0.0
condition	0	6	0.0
subroutine	4	17	23.5
pod	9	9	100.0
total	25	196	12.7

package SQL::Easy;
{
  $SQL::Easy::VERSION = '2.0.0';
}

# ABSTRACT: extremely easy access to sql data



use strict;
use warnings;

use DBI;
use Carp;



sub new {
    my ($class, @params) = @_;

    if (ref $params[0] eq 'HASH') {
        croak "Incorrect usage of SQL::Easy->new()."
            . " Since version 2.0.0 SQL::Easy->new() need to recieve hash, not hashref."
            ;
    }
    my %params = @params;

    my $self  = {};

    $self->{dbh} = $params{dbh};
    $self->{connection_check_threshold} = $params{connection_check_threshold} || 30;
    $self->{count} = 0;

    unless ($self->{dbh}) {
        $self->{settings} = {
            db         => $params{database},
            user       => $params{user},
            password   => $params{password},
            host       => $params{host} || '127.0.0.1',
            port       => $params{port} || 3306,
        };

        $self->{dbh} = _get_connection($self->{settings});
    };

    $self->{last_connection_check} = time;

    if (defined $params{debug}) {
        croak "Incorrect usage of SQL::Easy->new()."
            . " Since version 2.0.0 SQL::Easy has no 'debug' parameter in new()."
            ;
    }

    my $cb_before_execute = delete $params{cb_before_execute};
    if (defined $cb_before_execute) {
        croak "cb_before_execute should be coderef"
            if ref($cb_before_execute) ne 'CODE';
        $self->{_cb_before_execute} = $cb_before_execute;
    }

    bless($self, $class);
    return $self;
}


sub get_dbh {
    my ($self) = @_;

    $self->_reconnect_if_needed();

    return $self->{dbh};
}


sub get_one {
    my ($self, $sql, @bind_variables) = @_;

    $self->_reconnect_if_needed();

    my $sth = $self->{dbh}->prepare($sql);
    $self->_run_cb_before_execute($sql, @bind_variables);
    $sth->execute(@bind_variables) or croak $self->{dbh}->errstr;

    my @row = $sth->fetchrow_array;

    return $row[0];
}


sub get_row {
    my ($self, $sql, @bind_variables) = @_;

    $self->_reconnect_if_needed();

    my $sth = $self->{dbh}->prepare($sql);
    $self->_run_cb_before_execute($sql, @bind_variables);
    $sth->execute(@bind_variables) or croak $self->{dbh}->errstr;

    my @row = $sth->fetchrow_array;

    return @row;
}


sub get_col {
    my ($self, $sql, @bind_variables) = @_;
    my @return;

    $self->_reconnect_if_needed();

    my $sth = $self->{dbh}->prepare($sql);
    $self->_run_cb_before_execute($sql, @bind_variables);
    $sth->execute(@bind_variables) or croak $self->{dbh}->errstr;

    while (my @row = $sth->fetchrow_array) {
        push @return, $row[0];
    }

    return @return;
}


sub get_data {
    my ($self, $sql, @bind_variables) = @_;
    my @return;

    $self->_reconnect_if_needed();

    my $sth = $self->{dbh}->prepare($sql);
    $self->_run_cb_before_execute($sql, @bind_variables);
    $sth->execute(@bind_variables) or croak $self->{dbh}->errstr;

    my @cols = @{$sth->{NAME}};

    my @row;
    my $line_counter = 0;
    my $col_counter = 0;

    while (@row = $sth->fetchrow_array) {
        $col_counter = 0;
        foreach(@cols) {
            $return[$line_counter]{$_} = ($row[$col_counter]);
            $col_counter++;
        }
        $line_counter++;
    }

    return \@return;
}


sub get_tsv_data {
    my ($self, $sql, @bind_variables) = @_;
    my $return;

    $self->_reconnect_if_needed();

    my $sth = $self->{dbh}->prepare($sql);
    $self->_run_cb_before_execute($sql, @bind_variables);
    $sth->execute(@bind_variables) or croak $self->{dbh}->errstr;

    $return .= join ("\t", @{$sth->{NAME}}) . "\n";

    while (my @row = $sth->fetchrow_array) {
        foreach (@row) {
            $_ = '' unless defined;
        }
        $return .= join ("\t", @row) . "\n";
    }

    return $return;
}


sub insert {
    my ($self, $sql, @bind_variables) = @_;

    $self->_reconnect_if_needed();

    my $sth = $self->{dbh}->prepare($sql);
    $self->_run_cb_before_execute($sql, @bind_variables);
    $sth->execute(@bind_variables) or croak $self->{dbh}->errstr;

    return $sth->{mysql_insertid};
}


sub execute {
    my ($self, $sql, @bind_variables) = @_;

    $self->_reconnect_if_needed();

    my $sth = $self->{dbh}->prepare($sql);
    $self->_run_cb_before_execute($sql, @bind_variables);
    $sth->execute(@bind_variables) or croak $self->{dbh}->errstr;

    return 1;
}


sub _run_cb_before_execute {
    my ($self, $sql, @bind_variables) = @_;

    if (defined $self->{_cb_before_execute}) {
        $self->{_cb_before_execute}->(
            sql => $sql,
            bind_variables => \@bind_variables,
        );
    }

    return '';
}


sub _reconnect_if_needed {
    my ($self) = @_;

    if (time - $self->{last_connection_check} > $self->{connection_check_threshold}) {
        if (_check_connection($self->{dbh})) {
            $self->{last_connection_check} = time;
        } else {
            $self->{dbh}= _get_connection($self->{settings});
        }
    }

}


sub _get_connection {
    my ($self) = @_;

    my $dsn = "DBI:mysql:database=" . $self->{db}
        . ";host=" . $self->{host}
        . ";port=" . $self->{port};

    my $dbh = DBI->connect(
        $dsn,
        $self->{user},
        $self->{password},
        {
            PrintError => 0,
            RaiseError => 1,
            mysql_auto_reconnect => 0,
            mysql_enable_utf8 => 1,
        },
    ) or croak "Can't connect to database. Error: " . $DBI::errstr . " . Stopped";

    return $dbh;
}


sub _check_connection {
    my $dbh = shift;
    return unless $dbh;
    if (my $result = $dbh->ping) {
        if (int($result)) {
            # DB driver itself claims all is OK, trust it:
            return 1;
        } else {
            # It was "0 but true", meaning the default DBI ping implementation
            # Implement our own basic check, by performing a real simple
            # query.
            my $ok;
            eval {
                $ok = $dbh->do('select 1');
            };
            return $ok;
        }
    } else {
        return;
    }
}


1;

__END__