File Coverage

blib/lib/Podman/Container.pm

Criterion	Covered	Total	%
statement	38	42	90.4
branch	3	6	50.0
condition	1	2	50.0
subroutine	15	16	93.7
pod	6	6	100.0
total	63	72	87.5

package Podman::Container;

use Mojo::Base 'Podman::Client';

use Exporter qw(import);
use List::Util qw(first);

use Podman::Image;

our @EXPORT_OK = qw(create);

has 'name' => sub { return '' };

sub create {
  my ($name, $image, %options) = @_;

  my $self = __PACKAGE__->new;

  $self->post('containers/create',
    data => {image => ref $image eq 'Podman::Image' ? $image->name : $image, name => $name, %options});

  return $self->name($name);
}

sub inspect {
  my $self = shift;

  my $data   = $self->get(sprintf "containers/%s/json", $self->name)->json;
  my $status = $data->{State}->{Status};
  $status = $status eq 'configured' ? 'created' : $status;

  return {
    Id      => $data->{Id},
    Image   => Podman::Image->new(name => $data->{ImageName}),
    Created => $data->{Created},
    Status  => $status,
    Cmd     => $data->{Config}->{Cmd},
    Ports   => $data->{HostConfig}->{PortBindings},
  };
}

sub kill {
  my ($self, $signal) = @_;

  $signal //= 'SIGTERM';

  $self->post((sprintf "containers/%s/kill", $self->name), parameters => {signal => $signal});

  return 1;
}

sub remove {
  my ($self, $force) = @_;

  $self->delete((sprintf "containers/%s", $self->name), parameters => {force => $force});

  return 1;
}

sub stats {
  my $self = shift;

  my $data  = $self->get('containers/stats', parameters => {stream => 0})->json;
  my $stats = first { $_->{Name} eq $self->name } @{$data->{Stats}};

  return unless $stats;
  return {
    CpuPercent => $stats->{CPU},
    MemUsage   => $stats->{MemUsage},
    MemPercent => $stats->{MemPerc},
    NetIO      => (sprintf "%d / %d", $stats->{NetInput},   $stats->{NetOutput}),
    BlockIO    => (sprintf "%d / %d", $stats->{BlockInput}, $stats->{BlockOutput}),
    PIDs       => $stats->{PIDs},
  };
}

sub systemd {
  my $self = shift;

  my $data = $self->get(sprintf "generate/%s/systemd", $self->name)->json;

  return (values %{$data})[0];
}

for my $name (qw(pause restart start stop unpause)) {
  Mojo::Util::monkey_patch(__PACKAGE__, $name,
    sub { my $self = shift; $self->post(sprintf "containers/%s/%s", $self->name, $name); return 1; });
}

1;

__END__