File Coverage

blib/lib/Perl/Dist/Padre.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

package Perl::Dist::Padre;

#<<<
use 5.008001;
use strict;
use warnings;
use Perl::Dist::WiX          1.200002;
use Perl::Dist::Strawberry   2.10     qw();
use URI::file                         qw();
use English                           qw( -no_match_vars );
use File::Spec::Functions             qw( catfile catdir );
use parent                            qw( Perl::Dist::Strawberry );
#>>>

# http://www.dagolden.com/index.php/369/version-numbers-should-be-boring/
our $VERSION = '0.630';
$VERSION =~ s/_//ms;



######################################################################
# Configuration

sub new {
	my $dist_dir = File::ShareDir::dist_dir('Perl-Dist-Padre');

	return shift->SUPER::new(

		# Define the distribution information and where it goes.
		app_id            => 'padre',
		app_name          => 'Strawberry Perl plus Padre',
		app_ver_name      => 'Strawberry Perl 5.10.1.2 plus Padre 0.62',
		app_publisher     => 'Padre',
		app_publisher_url => 'http://padre.perlide.org/',
		image_dir         => 'C:\strawberry',

		# Set e-mail to something Padre-specific.
		perl_config_cf_email => '[e-mail]',

		# The MSI stuff.
		msi_product_icon => catfile( $dist_dir, 'padre.ico' ),
		msi_help_url     => undef,
		msi_banner_top   => catfile( $dist_dir, 'PadreBanner.bmp' ),
		msi_banner_side  => catfile( $dist_dir, 'PadreDialog.bmp' ),

		# Perl version
		perl_version => '5101',

		# Program version.
		build_number => 1,

		# Trace level.
		trace => 1,

		# Build both exe and zip versions.
		msi => 1,
		zip => 1,

		# These are the locations to pull down the msm.
		msm_to_use =>
'http://strawberryperl.com/download/strawberry-msm/strawberry-perl-5.10.1.2.msm',
		msm_zip =>
		  'http://strawberryperl.com/download/strawberry-perl-5.10.1.2.zip',
		msm_code => 'BC4B680E-4871-31E7-9883-3E2C74EA4F3C',

		# Tasks to complete to create Strawberry + Padre.
		tasklist => [
			'final_initialization',
			'initialize_using_msm',
			'install_padre_prereq_modules_1',
			'install_padre_prereq_modules_2',
			'install_padre_modules',
			'install_win32_extras',
			'install_strawberry_extras',
			'install_padre_extras',
			'remove_waste',
			'regenerate_fragments',
			'write',
		],

		# Other parameters passed in override the ones
		# here and in Strawberrry.
		@_,
	);

} ## end sub new



sub output_base_filename {
	return 'strawberry-plus-padre-0.63';
}



#####################################################################
# Customisations for Perl assets

sub install_perl_589 {
	my $self = shift;
	PDWiX->throw('Perl 5.8.9 is not available in Padre Standalone');
	return;
}



sub install_perl_5100 {
	my $self = shift;
	PDWiX->throw('Perl 5.10.0 is not available in Padre Standalone');
	return;
}



sub install_perl_5120 {
	my $self = shift;
	PDWiX->throw('Perl 5.12.0 is not available in Padre Standalone');
	return;
}



sub install_perl_5121 {
	my $self = shift;
	PDWiX->throw('Perl 5.12.1 is not available in Padre Standalone');
	return;
}



sub install_padre_prereq_modules_1 {
	my $self = shift;

	# Manually install our non-Wx dependencies first to isolate
	# them from the Wx problems
	$self->install_modules( qw{
		  File::Glob::Windows
		  File::Next
		  App::Ack
		  Class::Adapter
		  Class::Inspector
		  Class::Unload
		  AutoXS::Header
		  Class::XSAccessor
		  Devel::Dumpvar
		  File::Copy::Recursive
		  File::ShareDir
		  File::ShareDir::PAR
		  Test::Object
		  Config::Tiny
		  Test::ClassAPI
		  Clone
		  Hook::LexWrap
	} );

	return 1;
} ## end sub install_padre_prereq_modules_1



sub install_padre_prereq_modules_2 {
	my $self = shift;

# Manually install our non-Wx dependencies first to isolate
# them from the Wx problems
# NOTE: ORLite::Migrate goes after ORLite once they don't clone it privately.
# NOTE: Test::Exception goes before Test::Most when it's not in Strawberry.
	$self->install_modules( qw{
		  Test::SubCalls
		  List::MoreUtils
		  PPI
		  Module::Locate
		  Perl::Tags
		  Module::Refresh
		  Devel::Symdump
		  Pod::Coverage
		  Test::Pod::Coverage
		  Test::Pod
		  Module::Starter
		  ORLite
		  Test::Differences
		  Pod::POM
		  Parse::ErrorString::Perl
		  Text::FindIndent
		  Pod::Abstract
		  Devel::StackTrace
		  Class::Data::Inheritable
		  Exception::Class
		  Test::Most
		  Parse::ExuberantCTags
		  CPAN::Mini
		  Portable
		  Capture::Tiny
		  prefork
		  PPIx::EditorTools
		  Spiffy
		  Test::Base
		  ExtUtils::XSpp
		  Locale::Msgfmt
		  Module::ScanDeps
		  Module::Install
		  Format::Human::Bytes
		  Template::Tiny
		  Win32::Shortcut
		  Debug::Client
		  Devel::Refactor
		  App::cpanminus
		  POD2::Base
		  Readonly
		  Readonly::XS
		  PPIx::Regexp
		  UNIVERSAL::isa
		  UNIVERSAL::can
		  Test::MockObject
	} );

	return 1;
} ## end sub install_padre_prereq_modules_2



sub install_padre_modules {
	my $self = shift;

	## no critic(RestrictLongStrings)
	# Install the Alien::wxWidgets module from a precompiled .par
	my $par_url =
'http://strawberryperl.com/download/padre/Alien-wxWidgets-0.50-MSWin32-x86-multi-thread-5.10.1.par';
	my $filelist = $self->install_par(
		name => 'Alien_wxWidgets',
		url  => $par_url,
	);

	# Install the Wx module over the top of alien module
	$self->install_module( name => 'Wx' );

	# Install modules that add more Wx functionality
	$self->install_module(
		name  => 'Wx::Perl::ProcessStream',
		force => 1                     # since it fails on vista
	);

	# And finally, install Padre itself
	$self->install_module( name => 'Padre', );

	return 1;
} ## end sub install_padre_modules

sub install_padre_extras {
	my $self = shift;

	# Check that the padre.exe exists
	my $to = catfile( $self->image_dir(), 'perl', 'bin', 'padre.exe' );
	if ( not -f $to ) {
		PDWiX->throw(q{The "padre.exe" file does not exist});
	}

	# Get the Id for directory object that stores the filename passed in.
	my $dir_id = $self->get_directory_tree()->search_dir(
		path_to_find => catdir( $self->image_dir(), 'perl', 'bin' ),
		exact        => 1,
		descend      => 1,
	)->get_id();

	my $icon_id =
	  $self->_icons()
	  ->add_icon( catfile( $self->dist_dir(), 'padre.ico' ), 'padre.exe' );

	# Add the start menu icon.
	$self->get_fragment_object('StartMenuIcons')->add_shortcut(
		name => 'Padre',
		description =>
'Perl Application Development and Refactoring Environment - a Perl IDE',
		target      => "[D_$dir_id]padre.exe",
		id          => 'Padre',
		working_dir => $dir_id,
		icon_id     => $icon_id,
	);

	return 1;
} ## end sub install_padre_extras



sub dist_dir {
	my $self = shift;

	my $dir;

	if ( not eval { $dir = File::ShareDir::dist_dir('Perl-Dist-Padre'); 1; }
	  )
	{
		PDWiX::Caught->throw(
			message =>
			  'Could not find distribution directory for Perl::Dist::Padre',
			info => ( defined $EVAL_ERROR ) ? $EVAL_ERROR : 'Unknown error',
		);
	}

	return $dir;
} ## end sub dist_dir

1;                                     # Magic true value required at end of module

__END__