File Coverage

blib/lib/Pandoc/Metadata.pm

Criterion	Covered	Total	%
statement	68	70	97.1
branch	31	34	91.1
condition	13	14	92.8
subroutine	20	21	95.2
pod			n/a
total	132	139	94.9

package Pandoc::Metadata;
use strict;
use warnings;
use 5.010001;

use Pandoc::Elements;
use Scalar::Util qw(blessed reftype);
use JSON::PP;

# packages and methods

{
    # key-value map of metadata fields
    package Pandoc::Document::Metadata;

    {
        no warnings 'once';
        *to_json = \&Pandoc::Document::Element::to_json;
    }

    sub TO_JSON {
        return { map { $_ => $_[0]->{$_} } keys %{ $_[0] } };
    }

    sub value {
        my $map = { c => shift };
        Pandoc::Document::MetaMap::value( $map, @_ )
    }
}

{
    # metadata element parent class
    package Pandoc::Document::Meta;
    our @ISA = ('Pandoc::Document::Element');
    sub is_meta { 1 }
    sub value { shift->value(@_) }
}

# methods

sub _value_args {
    my $content = shift->{c};
    my ($pointer, %opts) = @_ % 2 ? @_ : (undef, @_);

    $opts{pointer} = $pointer // $opts{pointer} // '';

    return ($content, %opts);
}

sub Pandoc::Document::MetaString::value {
    my ($content, %opts) = _value_args(@_);
    $opts{pointer} eq '' ? $content : undef;
}

sub Pandoc::Document::MetaBool::set_content {
    $_[0]->{c} = $_[1] && $_[1] ne 'false' && $_[1] ne 'FALSE' ? 1 : 0;
}

sub Pandoc::Document::MetaBool::TO_JSON {
    return {
        t => 'MetaBool',
        c => $_[0]->{c} ? JSON::true() : JSON::false(),
    };
}

sub Pandoc::Document::MetaBool::value {
    my ($content, %opts) = _value_args(@_);
    return if $opts{pointer} ne '';

    if (($opts{boolean} // '') eq 'JSON::PP') {
        $content ? JSON::true() : JSON::false();
    } else {
        $content ? 1 : 0;
    }
}

sub Pandoc::Document::MetaMap::value {
    my ($map, %opts) = _value_args(@_);

    if ($opts{pointer} eq '') {
        return { map { $_ => $map->{$_}->value(%opts) } keys %$map };
    } else {
        my ($key, @fields) = split '/', $opts{pointer};
        $key =~ s!~1!/!g;
        $key =~ s/~0/~/g;
        $opts{pointer} = join '/', @fields;
        return $map->{$key} ? $map->{$key}->value(%opts) : undef;
    }
}

sub Pandoc::Document::MetaList::value {
    my ($content, %opts) = _value_args(@_);
    if ($opts{pointer} =~ /^[1-9]*[0-9]$/) {
        my $value = $content->[$opts{pointer}];
        defined $value ? $value->value(%opts, pointer => '') : undef;
    } elsif ($opts{pointer} eq '') {
        [ map { $_->value(%opts) } @$content ]
    } else {
        undef
    }
}

sub Pandoc::Document::MetaInlines::value {
    my ($content, %opts) = _value_args(@_);
    return if $opts{pointer} ne '';

    if ($opts{element} // '' eq 'keep') {
        $content;
    } else {
        join '', map { $_->string } @$content;
    }
}

sub Pandoc::Document::MetaBlocks::string {
    join "\n\n", map { $_->string } @{$_[0]->content};
}

sub Pandoc::Document::MetaBlocks::value {
    my ($content, %opts) = _value_args(@_);
    return if $opts{pointer} ne '';

    if ($opts{element} // '' eq 'keep') {
        $content;
    } else {
        $_[0]->string;
    }
}

1;
__END__