File Coverage

blib/lib/POE/Filter/Finger.pm

Criterion	Covered	Total	%
statement	43	53	81.1
branch	8	8	100.0
condition	2	6	33.3
subroutine	7	10	70.0
pod	6	6	100.0
total	66	83	79.5

package POE::Filter::Finger;

use strict;
use warnings;
use vars qw($VERSION);
use base qw(POE::Filter);

$VERSION = '0.08';

#  {Q1}    ::= [{W}|{W}{S}{U}]{C}
#  {Q2}    ::= [{W}{S}][{U}]{H}{C}
#  {U}     ::= username
#  {H}     ::= @hostname | @hostname{H}
#  {W}     ::= /W
#  {S}     ::=  | {S}
#  {C}     ::=

my $u_regex = qr{[a-z0-9.]+}i;
my $h_regex = qr{[-_a-z0-9.]+}i;

sub new {
  my $class = shift;
  my $self = {@_};
  $self->{BUFFER} = [];
  bless $self, $class;
}

sub get_one_start {
  my ($self, $raw) = @_;
  push @{ $self->{BUFFER} }, $_ for @$raw;
}

sub get_one {
  my $self = shift;
  my $events = [];

  my $query = shift @{ $self->{BUFFER} };

  return $events unless defined $query;

  my $original = $query;
  my $verbose = $query =~ s{\A/W\s*}{};
  my $user_regex = $self->{username_regex} || $u_regex;
  my $host_regex = $self->{hostname_regex} || $h_regex;

  SWITCH: {
    if ($query eq '') {
      push @$events, { listing => { verbose => $verbose } };
      last SWITCH;
    }
    if ($query =~ /\A$user_regex\z/) {
      push @$events, { user => { username => $query, verbose => $verbose } };
      last SWITCH;
    }
    if ($query =~ /\A($user_regex)?((?:\@$host_regex)+)\z/) {
      my ($username, $host_string) = ($1, $2);
      my @hosts = split /@/, $host_string;
      shift @hosts;

      push @$events, { forward =>
      	{  username => $username,
           hosts    => \@hosts,
           verbose  => $verbose, }
      };
      last SWITCH;
    }
    push @$events, { unknown => $original };
  }

  return $events;
}

sub get_pending {
  my $self = shift;
  return $self->{BUFFER};
}

sub put {
  my ($self, $chunks) = @_;
  [ @$chunks ];
}

sub clone {
  my $self = shift;
  my $nself = { };
  $nself->{$_} = $self->{$_} for keys %{ $self };
  $nself->{BUFFER} = [ ];
  return bless $nself, ref $self;
}

'Finger meh!';
__END__