File Coverage

blib/lib/OpusVL/SimpleCrypto.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

use strict;
use warnings;
package OpusVL::SimpleCrypto;

# ABSTRACT: Very simple encryption methods.

use Moo;
use Crypt::Sodium;
use MIME::Base64;

our $VERSION = '0.008';

has key_string => (is => 'rw', lazy => 1, builder => '_build_key_string');
has key => (is => 'ro', lazy => 1, builder => '_build_key');
has deterministic_salt => (is => 'ro', lazy => 1, builder => '_build_deterministic_salt');
has deterministic_salt_string => (is => 'ro', lazy => 1, builder => '_build_deterministic_salt_string');

sub _build_deterministic_salt
{
    my $self = shift;
    die 'Must specify deterministic_salt or deterministic_salt_string' unless $self->deterministic_salt_string;
    return decode_base64($self->deterministic_salt_string);
}

sub _build_deterministic_salt_string
{
    my $self = shift;
    die 'Must specify deterministic_salt or deterministic_salt_string' unless $self->deterministic_salt;
    return encode_base64($self->deterministic_salt);
}

sub _build_key
{
    my $self = shift;
    die 'Must specify key or key_string' unless $self->key_string;
    return decode_base64($self->key_string);
}

sub _build_key_string
{
    my $self = shift;
    die 'Must specify key or key_string' unless $self->key;
    return encode_base64($self->key);
}

sub GenerateKey
{
    my $k = crypto_stream_key();
    my $salt = crypto_pwhash_salt();
    return OpusVL::SimpleCrypto->new({ key => $k, deterministic_salt => $salt });
}

sub encrypt
{
    my $self = shift;
    my $message = shift;
    my $n = crypto_stream_nonce();
    my $t = crypto_secretbox($message, $n, $self->key);
    return sprintf("%s:%s", encode_base64($n), encode_base64($t));
}

sub encrypt_deterministic
{
    my $self = shift;
    my $message = shift;
    my $salt = $self->deterministic_salt;
    my $n = crypto_pwhash_scrypt($message, $salt, crypto_stream_NONCEBYTES);
    my $t = crypto_secretbox($message, $n, $self->key);
    return sprintf("%s:%s", encode_base64($n), encode_base64($t));
}

sub decrypt
{
    my $self = shift;
    my $ciphertext = shift;
    my ($nonce, $cipher) = split /:/, $ciphertext;
    return crypto_secretbox_open(decode_base64($cipher), decode_base64($nonce), $self->key);
}


1;

__END__