File Coverage

blib/lib/OpenPlugin/Session/ApacheSession.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

package OpenPlugin::Session::ApacheSession;

# $Id: ApacheSession.pm,v 1.5 2003/06/10 00:30:23 andreychek Exp $

use strict;
use OpenPlugin::Session();
use base        qw( OpenPlugin::Session );
use Apache::Session::Flex();

$OpenPlugin::Session::ApacheSession::VERSION = sprintf("%d.%02d", q$Revision: 1.5 $ =~ /(\d+)\.(\d+)/);


sub init {
    my ( $self, $args ) = @_;

    my $params = $self->_init_params;

    # FIXME -- I'm not sure this belongs here.  Could we somehow add "File" as
    # a datasource type, and upon a 'connect', do a permissions check?
    if ($params->{Store} eq "File") {
        # Can we write to the session dir, and is it really a directory?
        unless (-w $params->{Directory} and -d $params->{Directory}) {

            # We only do this is it's really a dir, and it's writable
            $params->{Directory} =~ /^(.*)$/;
            $params->{Directory} = $1;

            unless (mkdir $params->{Directory}, 0760) {
                $self->OP->exception->throw(
                    "The session dir ($params->{Directory}) is not writable " .
                    "by the Apache's httpd process! Please change the owner " .
                    "of that directory to the user ID your webserver is "     .
                    "running as."
                );
            }
        }
        # Can we write to the lockfile dir, and is it really a directory?
        unless (-w $params->{LockDirectory} and -d $params->{LockDirectory}) {

            # We only do this is it's really a dir, and it's writable
            $params->{LockDirectory} =~ /^(.*)$/;
            $params->{LockDirectory} = $1;

            unless (mkdir $params->{LockDirectory}, 0760) {
                $self->OP->exception->throw(
                    "The lock dir ($params->{LockDirectory}) is not writable ".
                    "by the Apache's httpd process! Please change the owner " .
                    "of that directory to the user ID your webserver is "     .
                    "running as."
                );
            }
        }
    }

    return $self;
}

# This session connects to the session, and returns data in it as a hashref
sub get_session_data {
    my ( $self, $session_id ) = @_;

    my $params = $self->_init_params;

    my %session = ();

    eval { tie %session, 'Apache::Session::Flex', $session_id, { %$params }; };
    if ( $@ ) {
        $self->OP->log->warn( "Failed to initiate session: $@" );
        return undef;
    }

    return ( \%session );

}

sub _init_params {
    my $self = shift;

    my $params =
        $self->OP->config->{'plugin'}{'session'}{'driver'}{'ApacheSession'};

    # Some reasonable (IMHO) defaults if we haven't been told certain parameters
    $params->{Store}         ||= "File";
    $params->{Lock}          ||= "Null";
    $params->{Generate}      ||= "MD5";
    $params->{Serialize}     ||= "Storable";

    # Untaint values Apache::Session uses as module names
    foreach my $key ( qw( Store Serialize Lock Generate ) ) {
        $params->{ $key } =~ m/^([-\w]+)$/;
        $params->{ $key } = $1;
    }

    if ( $params->{Store} eq "File" ) {
        $params->{Directory}     ||= "/tmp";
        $params->{LockDirectory} ||= "/tmp";

        if ( -d $params->{Directory} ) {
            $params->{Directory} =~ m/^(.*)$/;
            $params->{Directory} = $1;
        }

        if ( -d $params->{LockDirectory} ) {
            $params->{LockDirectory} =~ m/^(.*)$/;
            $params->{LockDirectory} = $1;
        }

    }

    if ( $self->OP->config->{'plugin'}{'session'}{'datasource'} ) {

        $params->{'Handle'} =
         $self->OP->datasource->connect( $self->OP->config->{'plugin'}{'session'}{'datasource'} );
    }

    return $params;
}

1;

__END__