File Coverage

blib/lib/Net/IPInfoDB.pm

Criterion	Covered	Total	%
statement	21	60	35.0
branch	0	12	0.0
condition			n/a
subroutine	7	14	50.0
pod	4	5	80.0
total	32	91	35.1

package Net::IPInfoDB;

# ----------------------------------------------------------------------
# Net::IPInfoDB - fetch ip info form ipinfodb.com
# ----------------------------------------------------------------------

use strict;
use vars qw($VERSION $DEBUG @FIELDS);
use vars qw($API_URI $API_VERSION);
use vars qw($WEB_URI);

use LWP::Simple qw(get);
use URI;

$VERSION = '3.0';
$DEBUG = 0 unless defined $DEBUG;

$API_URI = 'http://api.ipinfodb.com';
$API_VERSION = 'v3';

$WEB_URI = 'http://ipinfodb.com/ip_locator.php?ip=';
@FIELDS = qw(status_code status_message ip_address country_code country_name
             region_name city_name zip_code latitude longitude timezone);

sub new {
    my $class = shift;

    my $self = bless {
        _KEY    => '',
        _ERROR  => '',
    } => $class;

    if (@_) {
        $self->key($_[0]);
    }
    elsif (my $k = $ENV{'IPINFODB_TOKEN'}) {
        $self->key($k);
    }

    return $self;
}

sub key {
    my $self = shift;

    if (@_) {
        $self->{ _KEY } = $_[0];
    }

    return $self->{ _KEY };
}

sub error {
    my $self = shift;

    if (@_) {
        $self->{'_ERROR'} = "@_";
        return;
    }

    return $self->{'_ERROR'};
}

sub get_city {
    my $self = shift;
    my $host = shift;

    return $self->_get('ip-city', $host);
}

sub get_country {
    my $self = shift;
    my $host = shift;

    return $self->_get('ip-country', $host);
}

sub _get {
    my $self = shift;
    my $meth = shift;
    my $addr = shift;
    my $raw;
    my $res = Net::IPInfoDB::Result->new;

    my $uri = URI->new("$API_URI/$API_VERSION/$meth");
    $uri->query_form(
        format  => "raw",
        key     => $self->key,
        ip      => $addr,
    );

    if ($raw = get($uri)) {
        my @f = split /;/, $raw;
        for (my $i = 0; $i < @f; $i++) {
            my $m = $FIELDS[ $i ];
            $res->$m($f[ $i ]);
        }
    }


    if ($res->status_code ne "OK") {
        return $self->error($res->status_message);
    }

    $res->web_uri("$WEB_URI$addr");
    $res->_raw($raw);

    return $res;
}

package Net::IPInfoDB::Result;

use Class::Struct;

struct(
    (map { $_ => '$' } @Net::IPInfoDB::FIELDS),
    'web_uri' => '$',
    '_raw'    => '$',
);

sub fields {
    return @Net::IPInfoDB::FIELDS;
}

1;

__END__