File Coverage

blib/lib/Net/DNS/RR/TXT.pm

Criterion	Covered	Total	%
statement	48	48	100.0
branch	8	8	100.0
condition	2	2	100.0
subroutine	12	12	100.0
pod	1	2	100.0
total	71	72	100.0

package Net::DNS::RR::TXT;

use strict;
use warnings;
our $VERSION = (qw$Id: TXT.pm 1911 2023-04-17 12:30:59Z willem $)[2];

use base qw(Net::DNS::RR);

=encoding utf8


=head1 NAME

Net::DNS::RR::TXT - DNS TXT resource record

=cut

use integer;

use Carp;
use Net::DNS::Text;


sub _decode_rdata {			## decode rdata from wire-format octet string
	my ( $self, $data, $offset ) = @_;

	my $limit = $offset + $self->{rdlength};
	my $text;
	my $txtdata = $self->{txtdata} = [];
	while ( $offset < $limit ) {
		( $text, $offset ) = Net::DNS::Text->decode( $data, $offset );
		push @$txtdata, $text;
	}

	croak('corrupt TXT data') unless $offset == $limit;	# more or less FUBAR
	return;
}


sub _encode_rdata {			## encode rdata as wire-format octet string
	my $self = shift;

	my $txtdata = $self->{txtdata};
	return join '', map { $_->encode } @$txtdata;
}


sub _format_rdata {			## format rdata portion of RR string.
	my $self = shift;

	my $txtdata = $self->{txtdata};
	return ( map { $_->unicode } @$txtdata );
}


sub _parse_rdata {			## populate RR from rdata in argument list
	my ( $self, @argument ) = @_;

	$self->{txtdata} = [map { Net::DNS::Text->new($_) } @argument];
	return;
}


sub txtdata {
	my ( $self, @value ) = @_;

	$self->{txtdata} = [map { Net::DNS::Text->new($_) } @value] if scalar @value;

	my $txtdata = $self->{txtdata} || [];

	return ( map { $_->value } @$txtdata ) if wantarray;

	return defined(wantarray) ? join( ' ', map { $_->value } @$txtdata ) : '';
}


sub char_str_list { return my @txt = &txtdata }			# uncoverable pod


1;
__END__