File Coverage

blib/lib/Net/Async/Ping/TCP.pm

Criterion	Covered	Total	%
statement	28	29	96.5
branch	4	6	66.6
condition	4	9	44.4
subroutine	8	9	88.8
pod	0	1	0.0
total	44	54	81.4

package Net::Async::Ping::TCP;
$Net::Async::Ping::TCP::VERSION = '0.001001';
use Moo;
use warnings NONFATAL => 'all';

use Future;
use POSIX 'ECONNREFUSED';
use Time::HiRes;

use namespace::clean;

has default_timeout => (
   is => 'ro',
   default => 5,
);

has service_check => ( is => 'rw' );

has bind => ( is => 'rw' );

has port_number => (
   is => 'rw',
   default => 7,
);

sub ping {
   my ($self, $loop, $host, $timeout) = @_;
   $timeout ||= $self->default_timeout;

   my $service_check = $self->service_check;

   my $t0 = [Time::HiRes::gettimeofday];

   return Future->wait_any(
      $loop->connect(
         host     => $host,
         service  => $self->port_number,
         socktype => 'stream',
         ($self->bind ? (
            local_host => $self->bind,
         ) : ()),
      ),
      $loop->timeout_future(after => $timeout)
   )
   ->then(
      sub { Future->done(Time::HiRes::tv_interval($t0)) },
      sub {
         my ($human, $layer) = @_;
         my $ex    = pop;
         if ($layer && $layer eq 'connect') {
            return Future->done(Time::HiRes::tv_interval($t0))
               if !$service_check && $ex == ECONNREFUSED;
         }
         Future->fail(Time::HiRes::tv_interval($t0))
      },
   )
}

1;

__END__