File Coverage

blib/lib/Net/Airbrake.pm

Criterion	Covered	Total	%
statement	60	62	96.7
branch	5	8	62.5
condition	4	8	50.0
subroutine	15	15	100.0
pod	4	4	100.0
total	88	97	90.7

package Net::Airbrake;

use strict;
use warnings;

our $VERSION = '0.01';

use HTTP::Tiny;
use JSON qw(decode_json);
use Scope::Guard qw(guard);
use Net::Airbrake::Request;
use Net::Airbrake::Error;

use Class::Tiny {
    api_key     => undef,
    project_id  => undef,
    environment => $ENV{AIRBRAKE_ENV} || $ENV{PLACK_ENV} || 'default',
    _errors     => sub { [] },
    _ua         => sub { HTTP::Tiny->new(agent => "Net-Airbrake/$VERSION", timeout => 5) }
};

sub add_error {
    my $self = shift;
    my ($error) = @_;

    push @{$self->_errors}, Net::Airbrake::Error->new($error);
}

sub has_error {
    scalar @{shift->_errors} ? 1 : 0;
}

sub send {
    my $self = shift;
    my ($option) = @_;

    return unless $self->has_error;

    $self->_conceal_options($option);

    my $context = {
        os          => $^O,
        language    => "Perl $^V",
        environment => $self->environment,
        %{$option->{context} || {}},
    };
    my $req = Net::Airbrake::Request->new({
        errors      => $self->_errors,
        context     => $context,
        environment => $option->{environment} || {},
        session     => $option->{session}     || {},
        params      => $option->{params}      || {},
    });

    my $guard = guard { $self->_errors([]) };
    my $res = $self->_ua->request(POST => $self->_url, {
        content => $req->to_json,
        headers => { 'Content-Type' => 'application/json' },
    });
    die "Request failed to Airbrake: @{[$res->{status}]} @{[$res->{reason}]} (@{[$res->{content}]})"
        unless $res->{success};

    decode_json($res->{content});
}

sub notify {
    my $self = shift;
    my ($error, $option) = @_;

    $self->add_error($error);
    $self->send($option);
}

sub _url {
    my $self = shift;

    "https://airbrake.io/api/v3/projects/@{[$self->project_id]}/notices?key=@{[$self->api_key]}";
}

sub _conceal_options {
    my $self = shift;
    my ($option) = @_;

    for my $opt (qw(environment session params)) {
        for my $key (grep { /(?:cookie|password)/i } keys %{$option->{$opt}}) {
            $option->{$opt}{$key} =~ s/./*/g;
        }
    }
}

1;
__END__