File Coverage

blib/lib/Nanoid.pm

Criterion	Covered	Total	%
statement	51	51	100.0
branch	9	10	90.0
condition	6	7	85.7
subroutine	11	11	100.0
pod	0	1	0.0
total	77	80	96.2

package Nanoid;
use 5.010;
use strict;
use warnings;

our $VERSION = "0.04";

use strict;
use warnings;

use POSIX qw(ceil);
use Carp qw(croak);
use Bytes::Random::Secure qw(random_bytes);

use constant DEFAULT_SIZE => 21;
use constant DEFAULT_ALPHABETS =>
    '_-0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ';

sub generate {
    my (%opts) = @_;

    my $size     = $opts{size}     // DEFAULT_SIZE;
    my $alphabet = $opts{alphabet} // DEFAULT_ALPHABETS;

    my $alphabet_size = length $alphabet;

    if ( $size <= 0 ) {
        croak 'size must be greater than zero';
    }

    if ( $alphabet_size == 0 || $alphabet_size > 255 ) {
        croak 'alphabet must not empty and contain no more than 255 chars';
    }

    my @alphabet_array = split( '', $alphabet );
    my $mask = ( 2 << ( log( $alphabet_size - 1 ) / log(2) ) ) - 1;

    my $step = ceil( 1.6 * $mask * $size / $alphabet_size );
    my $id   = '';

    while (1) {
        my $bytes = [ unpack( 'C*', random_bytes($step) ) ];

        for my $idx ( 0 .. $step ) {
            my $byte;

            if ( defined $bytes->[$idx] ) {
                $byte = $bytes->[$idx] & $mask;

                if ( defined $alphabet_array[$byte] ) {
                    $id .= $alphabet_array[$byte];
                }
            }

            if ( length $id == $size ) {
                return $id;
            }
        }
    }

}

1;
__END__