File Coverage

lib/MouseX/Types/URI.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch			n/a
condition			n/a
subroutine	13	13	100.0
pod			n/a
total	52	52	100.0

package MouseX::Types::URI;

use 5.008_001;
use strict;
use warnings;
use Scalar::Util ();
use URI;
use URI::file;
use URI::data;
use URI::WithBase;
use URI::FromHash ();
use Mouse::Util::TypeConstraints;
use MouseX::Types -declare => [qw(Uri FileUri DataUri)]; # export types
use MouseX::Types::Mouse qw(Str ScalarRef HashRef);
use MouseX::Types::Path::Class qw(File Dir);

our $VERSION = '0.03';

type 'URI', # doesn't use class_type 'URI'
    where { Scalar::Util::blessed($_) and ($_->isa('URI') or $_->isa('URI::WithBase')) };

class_type 'URI::file';
class_type 'URI::data';

subtype Uri,     as 'URI';
subtype FileUri, as 'URI::file';
subtype DataUri, as 'URI::data';

for my $type ( 'URI', Uri ) {
    coerce($type,
        from Str,                 via { URI->new($_) },
        from ScalarRef,           via { my $u = URI->new('data:'); $u->data($$_); $u },
        from HashRef,             via { URI::FromHash::uri(%$_) },
        from File,                via { URI::file->new($_) },
        from Dir,                 via { URI::file->new($_) },
        from 'Path::Class::Dir',  via { URI::file->new($_) },
        from 'Path::Class::File', via { URI::file->new($_) },
    );
}

for my $type ( 'URI::file', FileUri ) {
    coerce($type,
        from Str,                 via { URI::file->new($_) },
        from File,                via { URI::file->new($_) },
        from Dir,                 via { URI::file->new($_) },
        from 'Path::Class::Dir',  via { URI::file->new($_) },
        from 'Path::Class::File', via { URI::file->new($_) },
    );
}

for my $type ( 'URI::data', DataUri ) {
    coerce($type,
        from Str, via {
            /^data:/ ? URI->new($_) : do { my $u = URI->new('data:'); $u->data($_); $u }
        },
        from ScalarRef, via {
            $$_ =~ /^data:/ ? URI->new($$_) : do { my $u = URI->new('data:'); $u->data($$_); $u }
        },
    );
}

1;

=head1 NAME

MouseX::Types::URI - A URI type library for Mouse

=head1 SYNOPSIS

=head2 CLASS TYPES

  package MyApp;
  use Mouse;
  use MouseX::Types::URI;

  has 'uri' => (
      is     => 'rw',
      isa    => 'URI',
      coerce => 1,
  );

  has 'data' => (
      is     => 'rw',
      isa    => 'URI::data',
      coerce => 1,
  );

  has 'file' => (
      is     => 'rw',
      isa    => 'URI::file',
      coerce => 1,
  );

=head2 CUSTOM TYPES

  package MyApp;
  use Mouse;
  use MouseX::Types::URI qw(Uri DataUri FileUri);

  has 'uri' => (
      is     => 'rw',
      isa    => Uri,
      coerce => 1,
  );

  has 'data' => (
      is     => 'rw',
      isa    => DataUri,
      coerce => 1,
  );

  has 'file' => (
      is     => 'rw',
      isa    => FileUri,
      coerce => 1,
  );

=head1 DESCRIPTION

MouseX::Types::URI creates common L types,
coercions and option specifications useful for dealing
with Ls as L attributes.

Coercions (see L) are made from
C, C, C,
L and L to
L, L and L objects.

=head1 TYPES

=head2 Uri

=over 4

Either L or L.

Coerces from C via L.

Coerces from L and L via L.

Coerces from C via L.

Coerces from C using L.

=back

=head2 DataUri

=over 4

A URI whose scheme is C.

Coerces from C and C via L.

=back

=head2 FileUri

=over 4

A L class type.

Coerces from C, L and L via L

=back

=head1 AUTHOR

NAKAGAWA Masaki [e-mail]

=head1 THANKS TO

Yuval Kogman, L

=head1 LICENSE

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=head1 SEE ALSO

L, L,

L, L, L, L, L,

L

=cut