File Coverage

blib/lib/Mojolicious/Plugin/ToolkitRenderer.pm

Criterion	Covered	Total	%
statement	32	39	82.0
branch	3	12	25.0
condition	5	20	25.0
subroutine	9	9	100.0
pod	1	1	100.0
total	50	81	61.7

package Mojolicious::Plugin::ToolkitRenderer;
# ABSTRACT: Template Toolkit Renderer Mojolicious Plugin

use 5.010;
use strict;
use warnings;

use Mojo::Base 'Mojolicious::Plugin';
use Mojo::Exception;

BEGIN {
    local $SIG{__WARN__} = sub {};
    require Template;
    Template->import;
}

our $VERSION = '1.11'; # VERSION

sub register {
    my ( $self, $app, $settings ) = @_;

    $settings->{config}{RELATIVE}     //= 1;
    $settings->{config}{EVAL_PERL}    //= 0;
    $settings->{config}{INCLUDE_PATH} //= $app->renderer->paths;

    my $template = Template->new( $settings->{config} );

    $settings->{context}->( $template->context ) if ( $settings->{context} );

    $app->renderer->add_handler( tt => sub {
        my ( $renderer, $controller, $output, $options ) = @_;
        my $inline = $settings->{settings}{inline_template} || 'inline';

        $template->process(
            ( ( $options->{$inline} ) ? \$options->{$inline} : $renderer->template_name($options) ),
            {
                content => $controller->content,
                %{ $controller->stash },
                ( $settings->{settings}{controller} || 'c' ) => $controller,
            },
            $output,
        ) || do {
            if ( ref( $settings->{settings}{error_handler} ) eq 'CODE' ) {
                $settings->{settings}{error_handler}->( $controller, $renderer, $app, $template );
            }
            else {
                unless (
                    $template->error and (
                        $template->error eq 'file error - exception.html.tt: not found' or
                        $template->error eq 'file error - exception.' . $app->mode . '.html.tt: not found'
                    )
                ) {
                    $$output = $template->error;
                    $controller->res->headers->content_type('text/plain');

                    $controller->log->error( $template->error );
                    $controller->rendered(
                        ( $template->error and $template->error =~ /not found/ ) ? 404 : 500
                    );
                }
            }
        };

        return $$output;
    } );

    $app->helper(
        render_tt => sub {
            shift->render( handler => 'tt', @_ );
        }
    );

    return;
}

1;

__END__