File Coverage

blib/lib/Mojolicious/Plugin/Facets.pm

Criterion	Covered	Total	%
statement	90	90	100.0
branch	20	24	83.3
condition	2	3	66.6
subroutine	13	13	100.0
pod	1	1	100.0
total	126	131	96.1

package Mojolicious::Plugin::Facets;

use Mojo::Base 'Mojolicious::Plugin';
use Mojolicious::Routes;
use Mojolicious::Static;
use Mojolicious::Sessions;
use Mojo::Cache;
use Mojo::Path;
use constant DEBUG => $ENV{DEBUG_FACETS};

our $VERSION = "0.07";


my @facets;

sub register {
    my ($self, $app, $config) = @_;

    $app->hook(around_dispatch => \&_detect_facet);

    $app->helper(facet_do => \&_facet_do);

    $app->helper(has_facet => sub {
        my ($c, $name) = @_;
        return unless $name;
        for (@facets) {
            return 1 if $_->{name} eq $name;
        }
        return;
    });

    $app->helper(add_facet => sub {
        shift;
        $self->_add_facet($app, @_);
    });

    foreach my $facet_name (keys %$config) {
        $self->_add_facet($app, $facet_name, $config->{$facet_name});
    }
}

sub _add_facet {
    my ($self, $app, $facet_name, $facet_config) = @_;

    die "Missing 'setup' key on facet '$facet_name' config." unless $facet_config->{setup};
    die "Missing 'host' or 'path' key on facet '$facet_name' config."
        unless $facet_config->{host} || $facet_config->{path};

    my $facet = {
        name => $facet_name,
        host => $facet_config->{host},
        routes => Mojolicious::Routes->new(namespaces => [@{ $app->routes->namespaces }]),
        static => Mojolicious::Static->new,
        sessions => Mojolicious::Sessions->new,
        renderer_paths => [@{ $app->renderer->paths }],
        renderer_cache => Mojo::Cache->new,
        $facet_config->{path} ? ( path => Mojo::Path->new($facet_config->{path})->leading_slash(1)->trailing_slash(0) ) : (),
    };

    # localize
    local $app->{routes} = $facet->{routes};
    local $app->{static} = $facet->{static};
    local $app->{sessions} = $facet->{sessions};
    local $app->renderer->{paths} = $facet->{renderer_paths};
    local $app->renderer->{cache} = $facet->{renderer_cache};

    # setup
    $facet_config->{setup}->($app);

    # store
    push @facets, $facet;
}


sub _detect_facet {
    my ($next, $c) = @_;

    # detect facet
    my $active_facet;
    my $req_host = $c->req->headers->host;
    $req_host =~ s/:\d+$//;

    foreach my $facet (@facets) {

        my $match = 0;

        if ($facet->{host}) {
            $match = 1 if $req_host eq $facet->{host};
        }

        if ($facet->{path}) {

            if ($c->req->url->path->contains($facet->{path})) {
                $match = 1;

                # rebase
                my $path_length = scalar @{$facet->{path}};
                my $base_path = $c->req->url->base->path->trailing_slash(1);
                my $req_path = $c->req->url->path->leading_slash(0);

                while ($path_length--) {
                    push @$base_path, shift @$req_path;
                }
            }
            else {
                $match = 0;
            }
        }

        if ($match) {
            $active_facet = $facet;
            last
        }
    }

    # localize relevant data and continue dispatch chain
    if ($active_facet) {
        DEBUG and $c->app->log->debug(qq/Dispatching facet "$active_facet->{name}"/);

        $c->stash->{'mojox.facet'} = $active_facet->{name};

        local $c->app->{routes} = $active_facet->{routes};
        local $c->app->{static} = $active_facet->{static};
        local $c->app->{sessions} = $active_facet->{sessions};
        local $c->app->renderer->{paths} = $active_facet->{renderer_paths};
        local $c->app->renderer->{cache} = $active_facet->{renderer_cache};
        $next->();
    }
    else {
        # no facet, continue dispatch
        $next->();
    }
}


sub _facet_do {
    my ($c, $facet_name, $code) = @_;

    my ($facet) = grep { $_->{name} eq $facet_name } @facets;
    die "Facet '$facet_name' do not exist." unless $facet;

    local $c->app->{routes} = $facet->{routes};
    local $c->app->{static} = $facet->{static};
    local $c->app->{sessions} = $facet->{sessions};
    local $c->app->renderer->{paths} = $facet->{renderer_paths};
    local $c->app->renderer->{cache} = $facet->{renderer_cache};
    local $c->{stash} = {};
    $code->($c);
}





1;
__END__