File Coverage

blib/lib/MojoX/Log/Rotate.pm

Criterion	Covered	Total	%
statement	54	54	100.0
branch	9	14	64.2
condition	3	7	42.8
subroutine	5	5	100.0
pod	1	4	25.0
total	72	84	85.7

package MojoX::Log::Rotate;
$MojoX::Log::Rotate::VERSION = '1.222630';
# ABSTRACT: Makes mojolicious log file rotation easy
use Mojo::Base 'Mojo::Log', -signatures;

has 'need_rotate_cb';
has 'rotate_cb';
has last_rotate => sub ($s) { $s->path && -f $s->path ? (stat $s->path)[10] : time() };
has frequency => 60 * 60 * 24; #every day

sub new ($class, %params)  {
  my %p = map  { $_ => delete $params{$_} }
          grep { exists $params{$_} }
          qw(frequency how when);
  my $self = $class->SUPER::new(%params);

  $self->frequency($p{frequency}) if exists $p{frequency};
  $self->rotate_cb($p{how} // \&default_rotation_cb);
  $self->need_rotate_cb($p{when} // \&default_need_rotation_cb);

  #inject our message subscrition on the top
  my $subscribers = $self->subscribers('message');
  $self->unsubscribe('message');
  $self->on(message => \&on_message_handler);
  $self->on(message => $_) for @$subscribers;

  $self;
}

sub on_message_handler ($self, $level, @args) {
  my $cb_when = $self->need_rotate_cb;
  my $cb_how  = $self->rotate_cb;
  if($cb_when && $cb_how) {
    if(my $when_res = $cb_when->($self)) {
      $self->last_rotate( time() );
      my $how_res = $cb_how->($self, $when_res);
      $self->emit('rotate' => { how => $how_res, when => $when_res });
    }
  }
}

# must returns a false value when there is no need to rotate, or a true value.
# the returns value will be passed to the rotate_cb so that you can share data between callback.
sub default_need_rotation_cb ($self) {
  return unless $self->path;
  if(time - $self->last_rotate > $self->frequency ) {
    my $last_rotate = $self->last_rotate;
    return { last_rotate => $last_rotate };
  }
  return;
}

sub default_rotation_cb ($self, $when_res) {
  require File::Copy;
  close $self->handle;
  my $res = { }; #nothing to rotate
  if(-f $self->path) {
    my ($y, $m, $d, $h, $mi, $s) =  (localtime)[5, 4, 3, 2, 1, 0];
    my $suffix = sprintf("_%04d%02d%02d_%02d%02d%02d", $y+1900, $m+1, $d, $h, $mi, $s);
    my $new_name = $self->path =~ s/(\.[^.]+)$/$suffix$1/r;
    File::Copy::move $self->path => $new_name
      or die "MojoX::Log::Rotation failed to move " . $self->path . " into $new_name : $!";
    $res = { rotated_file => $new_name };
  }
  $self->handle(Mojo::File->new($self->path)->open('>>'));
  return $res;
}

1;

__END__