File Coverage

blib/lib/MojoX/GlobalEvents.pm

Criterion	Covered	Total	%
statement	54	54	100.0
branch	10	10	100.0
condition	6	6	100.0
subroutine	11	11	100.0
pod	3	3	100.0
total	84	84	100.0

package MojoX::GlobalEvents;

# ABSTRACT: A module to handle events

use strict;
use warnings;

use File::Find::Rule;
use File::Spec;
use Mojo::File;
use Mojo::Util qw(class_to_path);
use Scalar::Util qw(blessed);

use base 'Exporter';
our @EXPORT = qw(on publish);

our $VERSION = '0.06';

my %subscriber;

sub init {
    my ($class, $namespace) = @_;

    die 'ERROR: Missing namespace to setup global event.'
        unless defined $namespace;

    my @spaces = split /::/, $namespace;
    my @dirs   = map{ File::Spec->catdir( $_, @spaces ) }@INC;
    my @files  = File::Find::Rule->file->name( '*.pm' )->in( @dirs );

    for my $file ( @files ) {
        my @parts = @{ Mojo::File->new( $file )->to_array };
        my $module = join '::', @parts;
        $module =~ s{.*?\Q$namespace\E}{$namespace};
        $module =~ s{\.pm\z}{};

        my $path = class_to_path $module;
        require $path;
    }
}

sub on {
    my $object = shift;

    my ($event,$sub) = @_;

    if ( !blessed $object ) {
        $sub    = $event;
        $event  = $object;
        $object = '';
    }

    return if ref $event or !ref $sub or ref $sub ne 'CODE';

    my $package = "$object";
    $package    = caller if !$package;
    $subscriber{$event}->{$package} = $sub;

    return 1;
}

sub publish {
    my ($event, @param) = @_;

    for my $package ( sort keys %{ $subscriber{$event} || {} } ) {
        $subscriber{$event}->{$package}->(@param);
    }

    return 1;
}


1;

__END__