File Coverage

blib/lib/Module/Format/PerlMF_App.pm

Criterion	Covered	Total	%
statement	15	57	26.3
branch	0	16	0.0
condition	0	3	0.0
subroutine	5	11	45.4
pod	2	2	100.0
total	22	89	24.7

package Module::Format::PerlMF_App;
$Module::Format::PerlMF_App::VERSION = '0.2.0';
use strict;
use warnings;

use Getopt::Long qw(GetOptionsFromArray);
use Pod::Usage;

use Module::Format::ModuleList;


sub new
{
    my $class = shift;
    my $self = bless {}, $class;
    $self->_init(@_);
    return $self;
}

sub _argv
{
    my $self = shift;

    if (@_)
    {
        $self->{_argv} = shift;
    }

    return $self->{_argv};
}

sub _init
{
    my ( $self, $args ) = @_;

    $self->_argv( [ @{ $args->{argv} } ] );

    return;
}


my %ops_to_formats = (
    'as_rpm_colon' => 'rpm_colon',
    'rpm_colon'    => 'rpm_colon',
    'as_rpm_c'     => 'rpm_colon',
    'rpm_c'        => 'rpm_colon',
    'as_rpm_dash'  => 'rpm_dash',
    'rpm_dash'     => 'rpm_dash',
    'as_rpm_d'     => 'rpm_dash',
    'rpm_d'        => 'rpm_dash',
    'dash'         => 'dash',
    'as_dash'      => 'dash',
    'colon'        => 'colon',
    'as_colon'     => 'colon',
    'deb'          => 'debian',
    'as_deb'       => 'debian',
    'debian'       => 'debian',
    'as_debian'    => 'debian',
);

sub run
{
    my ($self) = @_;

    my $argv = $self->_argv();

    my $op = shift(@$argv);

    if ( !defined($op) )
    {
        die "You did not specify any arguments - see --help";
    }

    if ( ( $op eq "-h" ) || ( $op eq "--help" ) )
    {
        pod2usage(1);
    }
    elsif ( $op eq "--man" )
    {
        pod2usage( -verbose => 2 );
    }

    if ( !exists( $ops_to_formats{$op} ) )
    {
        die "Unknown op '$op'.";
    }

    my $format = $ops_to_formats{$op};

    my $delim  = ' ';
    my $suffix = "\n";

    my $help = 0;
    my $man  = 0;
    if (
        !(
            my $ret = GetOptionsFromArray(
                $argv,
                '0!' => sub { $delim = "\0"; $suffix = q{}; },
                'n!' => sub { $delim = "\n"; $suffix = "\n"; },
                'help|h' => \$help,
                man      => \$man,
            )
        )
        )
    {
        die "GetOptions failed!";
    }

    if ($help)
    {
        pod2usage(1);
    }

    if ($man)
    {
        pod2usage( -verbose => 2 );
    }

    my @strings = @$argv;

    my $module_list_obj = Module::Format::ModuleList->sane_from_guesses(
        {
            values => \@strings,
        }
    );

    print join( $delim, @{ $module_list_obj->format_as($format) } ), $suffix;

    return;
}


1;    # End of Module::Format::PerlMF_App

__END__