File Coverage

blib/lib/Math/Vector/Similarity.pm

Criterion	Covered	Total	%
statement	43	43	100.0
branch	10	10	100.0
condition			n/a
subroutine	9	9	100.0
pod	5	5	100.0
total	67	67	100.0

package Math::Vector::Similarity;
# ABSTRACT: Cosine similarity, euclidean distance and other vector comparison functions
our $VERSION = '0.001';

use strict;
use warnings;
use Carp qw( croak );
use Exporter 'import';

our @EXPORT_OK = qw(
  cosine_similarity
  cosine_distance
  euclidean_distance
  dot_product
  normalize
);
our %EXPORT_TAGS = ( all => \@EXPORT_OK );

sub dot_product {
  my ( $a, $b ) = @_;
  croak "vectors must have same dimensions"
    unless @$a == @$b;
  my $sum = 0;
  $sum += $a->[$_] * $b->[$_] for 0..$#$a;
  return $sum;
}


sub normalize {
  my ( $vec ) = @_;
  my $norm = 0;
  $norm += $_ * $_ for @$vec;
  $norm = sqrt($norm);
  return $vec if $norm == 0;
  return [ map { $_ / $norm } @$vec ];
}


sub cosine_similarity {
  my ( $a, $b ) = @_;
  croak "vectors must have same dimensions"
    unless @$a == @$b;
  my ( $dot, $norm_a, $norm_b ) = ( 0, 0, 0 );
  for my $i (0..$#$a) {
    $dot    += $a->[$i] * $b->[$i];
    $norm_a += $a->[$i] * $a->[$i];
    $norm_b += $b->[$i] * $b->[$i];
  }
  my $denom = sqrt($norm_a) * sqrt($norm_b);
  return 0 if $denom == 0;
  return $dot / $denom;
}


sub cosine_distance {
  my ( $a, $b ) = @_;
  return 1 - cosine_similarity($a, $b);
}


sub euclidean_distance {
  my ( $a, $b ) = @_;
  croak "vectors must have same dimensions"
    unless @$a == @$b;
  my $sum = 0;
  for my $i (0..$#$a) {
    my $d = $a->[$i] - $b->[$i];
    $sum += $d * $d;
  }
  return sqrt($sum);
}


1;

__END__