File Coverage

blib/lib/Markdown/Compiler.pm

Criterion	Covered	Total	%
statement	31	35	88.5
branch	1	4	25.0
condition			n/a
subroutine	15	16	93.7
pod	0	1	0.0
total	47	56	83.9

# ABSTRACT: Perl Markdown Compiler
package Markdown::Compiler;
use Moo;
use Markdown::Compiler::Source;
use Markdown::Compiler::Lexer;
use Markdown::Compiler::Parser;
use Markdown::Compiler::Target::HTML;
use Module::Runtime qw( use_module );
use YAML::XS;

has source => (
    is       => 'ro',
    required => 1,
);

has _source => (
    is => 'ro',
    lazy => 1,
    builder => sub {
        Markdown::Compiler::Source->new( source => shift->source );
    }
);

has lexer => (
    is      => 'ro',
    lazy    => 1,
    builder => sub {
        Markdown::Compiler::Lexer->new( source => shift->_source->body );
    },
);

has parser => (
    is      => 'ro',
    lazy    => 1,
    builder => sub {
        Markdown::Compiler::Parser->new( stream => shift->stream );
    },
);

has stream => (
    is      => 'ro',
    lazy    => 1,
    builder => sub {
        shift->lexer->tokens;
    },
);

has tree => (
    is      => 'ro',
    lazy    => 1,
    builder => sub {
        shift->parser->tree;
    },
);

has compiler => (
    is      => 'ro',
    lazy    => 1,
    builder => sub {
        Markdown::Compiler::Target::HTML->new( tree => shift->tree );
    },
);

sub compiler_for {
    my ( $self, $target ) = @_;

    $target = substr($target,0,1) eq '+'
        ? substr($target,1)
        : 'Markdown::Compiler::Target::' . $target;

    return use_module("$target")->new( tree => $self->tree );
}

has result => (
    is      => 'ro',
    lazy    => 1,
    builder => sub {
        shift->compiler->result;
    }
);

has metadata => (
    is      => 'ro',
    lazy    => 1,
    builder => sub {
        my ( $self ) = @_;

        # Process YAML files with YAML::XS.
        if ( $self->_source->metatype eq 'YAML' ) {
            return Load( $self->_source->metadata );
        }

        return $self->_source->metadata;
    }
);

1;

__END__