File Coverage

blib/lib/Mail/SimpleList/Alias.pm

Criterion	Covered	Total	%
statement	65	65	100.0
branch	15	16	93.7
condition			n/a
subroutine	15	15	100.0
pod	8	9	88.8
total	103	105	98.1

package Mail::SimpleList::Alias;

use strict;
use warnings;

use Mail::Action::Address;
use Mail::Address;

use Class::Roles
    does => 'address_expires',
    does => 'address_named',
    does => 'address_described';

use vars qw( $VERSION );
$VERSION = '0.95';

sub new
{
    my $class = shift;
    bless {
        owner       => '',
        closed      => 0,
        expires     => 0,
        auto_add    => 1,
        description => '',
        members     => [],
    @_ }, $class;
}

sub members
{
    my $self = shift;
    return $self->{members};
}

sub add
{
    my $self = shift;

    my %existing = map { $_ => 1 } @{ $self->{members} };
    my $existing = @{ $self->{members} };

    while (@_)
    {
        my $address = shift or next;
        chomp $address;

        for my $member ( Mail::Address->parse( $address ))
        {
            $member = $member->address();
            next if exists $existing{ $member };
            push @{ $self->{members} }, $member;
            $existing{ $member } = 1;
        }
    }

    return @{ $self->{members} }[ $existing .. $#{ $self->{members} } ];
}

sub remove_address
{
    my ($self, $remove) = @_;

    # Mail::Address format adds a newline
    chomp $remove;
    my $original = @{ $self->{members} };

    $self->{members} = [ grep { $_ ne $remove } @{ $self->{members} } ];
    $self->{owner}   = '' if $self->{owner} eq $remove;

    return $original > @{ $self->{members} };
}

sub owner
{
    my $self = shift;
    $self->add( $self->{owner} = shift ) if @_;
    return $self->{owner};
}

sub closed
{
    my $self = shift;
    $self->{closed} = $self->is_true( $_[0] ) if @_;
    return $self->{closed};
}

sub is_true
{
    my ($self, $value) = @_;
    return 0 unless $value;
    return 0 if $value =~ /^[Nn]o/;
    return 1;

}

sub auto_add
{
    my $self = shift;
    $self->{auto_add} = $self->is_true( $_[0] ) if @_;
    return $self->{auto_add};
}

sub attributes
{
    +{ map { $_ => 1 } qw( owner closed expires auto_add description name ) }
}

1;
__END__