File Coverage

blib/lib/Mail/Exim/ACL/Geolocation.pm

Criterion	Covered	Total	%
statement	29	38	76.3
branch	3	8	37.5
condition			n/a
subroutine	7	8	87.5
pod	2	2	100.0
total	41	56	73.2

package Mail::Exim::ACL::Geolocation;

# SPDX-License-Identifier: Artistic-1.0-Perl OR GPL-1.0-or-later

use 5.016;
use warnings;
use utf8;

our $VERSION = 1.005;

use Exporter qw(import);
use IP::Geolocation::MMDB;

our @EXPORT_OK = qw(country_code asn_lookup);

my @directories = qw(
    /var/lib/GeoIP
    /usr/local/share/GeoIP
    /usr/share/GeoIP
    /opt/share/GeoIP
    /var/db/GeoIP
);

my @country_databases = qw(
    GeoIP2-Country.mmdb
    GeoIP2-City.mmdb
    dbip-country.mmdb
    dbip-city.mmdb
    GeoLite2-Country.mmdb
    GeoLite2-City.mmdb
    dbip-country-lite.mmdb
    dbip-city-lite.mmdb
);

my @asn_databases = qw(
    GeoIP2-ASN.mmdb
    dbip-asn.mmdb
    GeoLite2-ASN.mmdb
    dbip-asn-lite.mmdb
);

my $country_reader = eval {
    my $filename = $ENV{COUNTRY_DB}
        || _first_database(\@directories, \@country_databases);
    IP::Geolocation::MMDB->new(file => $filename);
};

my $asn_reader = eval {
    my $filename = $ENV{ASN_DB}
        || _first_database(\@directories, \@asn_databases);
    IP::Geolocation::MMDB->new(file => $filename);
};

sub country_code {
    my $ip_address = shift;

    return eval { $country_reader->getcc($ip_address) };
}

sub asn_lookup {
    my $ip_address = shift;

    my $asn_tag;
    my $asn = eval { $asn_reader->record_for_address($ip_address) };
    if (defined $asn) {
        my $number = $asn->{autonomous_system_number};
        if (defined $number) {
            $asn_tag = $number;
            my $organization = $asn->{autonomous_system_organization};
            if (defined $organization) {
                $asn_tag .= q{ } . $organization;
            }
        }
    }
    return $asn_tag;
}

sub _first_database {
    my ($directories, $databases) = @_;

    for my $dir (@{$directories}) {
        for my $db (@{$databases}) {
            my $filename = $dir . q{/} . $db;
            if (-r $filename) {
                return $filename;
            }
        }
    }
    return;
}

1;
__END__