File Coverage

blib/lib/List/Haystack.pm

Criterion	Covered	Total	%
statement	36	36	100.0
branch	10	10	100.0
condition	4	5	80.0
subroutine	9	9	100.0
pod	4	4	100.0
total	63	64	98.4

package List::Haystack;
use 5.008001;
use strict;
use warnings;
use Carp qw/croak/;

our $VERSION = "0.01";

sub new {
    my ($class, $list, $options) = @_;

    if (not defined $list) {
        $list = [];
    }

    if (ref $list ne 'ARRAY') {
         croak 'Type of given argument `$list` is not suitable. It must be array reference.';
    }

    my $self = bless {
        list => $list,
    }, $class;

    my $lazy = defined $options && ref($options) eq 'HASH' && $options->{lazy};
    if (not $lazy) {
        $self->_construct_haystack;
    }

    return $self;
}

sub haystack {
    my ($self) = @_;

    my $haystack = $self->{haystack};
    if (defined $haystack) {
        return $haystack;
    }

    # For lazy building
    return $self->_construct_haystack;
}

sub find {
    my ($self, $needle) = @_;

    return exists($self->haystack->{$needle}) ? 1 : 0;
}

sub cnt {
    my ($self, $needle) = @_;

    return $self->haystack->{$needle} || 0;
}

sub _construct_haystack {
    my ($self) = @_;

    my %haystack;
    for my $item (@{($self->{list})}) {
        $haystack{$item}++;
    }

    $self->{haystack} = \%haystack;
}

1;
__END__