File Coverage

blib/lib/Lingua/ZH/CCDICT/Romanization/Pinyin.pm

Criterion	Covered	Total	%
statement	43	43	100.0
branch	18	20	90.0
condition	6	6	100.0
subroutine	8	8	100.0
pod	2	3	66.6
total	77	80	96.2

package Lingua::ZH::CCDICT::Romanization::Pinyin;

use strict;
use warnings;

use base 'Lingua::ZH::CCDICT::Romanization';

my $umlaut_u = chr(252);

my %PinyinUnicode =
    ( a1 => chr(257),
      e1 => chr(275),
      i1 => chr(299),
      o1 => chr(333),
      u1 => chr(363),
      "${umlaut_u}1" => chr(470),

      a2 => chr(225),
      e2 => chr(233),
      i2 => chr(237),
      o2 => chr(243),
      u2 => chr(250),
      "${umlaut_u}2" => chr(472),

      a3 => chr(462),
      e3 => chr(283),
      i3 => chr(464),
      o3 => chr(466),
      u3 => chr(468),
      "${umlaut_u}3" => chr(474),

      a4 => chr(224),
      e4 => chr(232),
      i4 => chr(236),
      o4 => chr(242),
      u4 => chr(249),
      "${umlaut_u}4" => chr(476),
    );


sub new
{
    my $self = shift->SUPER::new(@_);

    # handle errors found in parent class
    return unless defined $self->{syllable};

    # there are a bunch of lX, mX, and nX, as well as one ng3
    return if $self->{syllable} =~ /^(?:l|m|n|ng)\d$/;

    $self->{ascii} = $self->{syllable};
    $self->{syllable} =~ s/uu/$umlaut_u/g;

    $self->_make_unicode_version();

    return $self;
}

sub as_ascii { $_[0]->{ascii} }

sub _make_unicode_version
{
    my $self = shift;

    my @syls = split /(?<=\d)/, $self->{syllable};

    $self->{pinyin_unicode} =
        join '', map { $self->_pinyin_as_unicode($_) } @syls;

    return $self;
}

sub _pinyin_as_unicode
{
    my $self = shift;
    my $syl = shift;

    my $num = chop $syl;

    unless ( $num =~ /[12345]/ )
    {
        warn "Bad pinyin (tone): $self->{syllable}\n" if $ENV{DEBUG_CCDICT_SOURCE};
        return;
    }

    # no tone marking
    return $syl if $num == 5;

    my @letters = split //, $syl;

    my $vowel_to_change;
    for ( my $x = 0; $x <= $#letters; $x++ )
    {
        if ( $letters[$x] =~ /[aeiou$umlaut_u]/ )
        {
            $vowel_to_change = $x;
            last;
        }
    }

    unless ( defined $vowel_to_change )
    {
        warn "Bad pinyin (no vowel to mark): $self->{syllable}\n" if $ENV{DEBUG_CCDICT_SOURCE};
        return;
    }

    if ( $letters[$vowel_to_change + 1] &&
         $letters[$vowel_to_change + 1] =~ /[aeiou$umlaut_u]/ )
    {
        # handle multiple vowels properly
        $vowel_to_change++
            unless ( $letters[$vowel_to_change + 1] eq 'u' ||
                     $letters[$vowel_to_change + 1] eq 'o' );
    }

    $letters[$vowel_to_change] = $PinyinUnicode{ $letters[$vowel_to_change] . $num };

    return join '', @letters;
}

sub as_unicode { $_[0]->{pinyin_unicode} }


1;

__END__