File Coverage

blib/lib/HTML5/Manifest.pm

Criterion	Covered	Total	%
statement	61	61	100.0
branch	21	30	70.0
condition	4	6	66.6
subroutine	9	9	100.0
pod	2	2	100.0
total	97	108	89.8

package HTML5::Manifest;
use strict;
use warnings;
our $VERSION = '0.04';

use Digest::MD5;
use File::Spec;
use IO::Dir;

sub new {
    my($class, %args) = @_;
    bless {
        %args
    }, $class;
}

sub _recurse {
    my($self, $path, $cb) = @_;

    my $dir = IO::Dir->new($path) or die "Can't open directory $path: $!";
    my @list;
    while (defined(my $entry = $dir->read)) {
        next if $entry eq File::Spec->updir || $entry eq File::Spec->curdir;
        push @list, $entry;
    }
    for my $entry (sort @list) {
        my $new_path = File::Spec->catfile($path, $entry);
        my $is_dir = -d $new_path;
        $entry = "$entry/" if $is_dir;
        my $is_pass = $cb->($new_path, $entry, $is_dir);
        next unless $is_pass;
        if ($is_dir) {
            $self->_recurse($new_path, $cb);
        }
    }
}

sub generate {
    my $self = shift;

    my $manifest = "CACHE MANIFEST\n\n";
    if ($self->{network} && ref $self->{network} eq 'ARRAY') {
        $manifest .= "NETWORK:\n";
        for my $path (@{ $self->{network} }) {
            $manifest .= "$path\n";
        }
        $manifest .= "\n";
    }

    my $md5;
    $md5 = Digest::MD5->new if $self->{use_digest};

    my $htdocs = $self->{htdocs};
    $htdocs =~ s!\\!/!g if $^O eq 'MSWin32';
    $manifest .= "CACHE:\n";
    $self->_recurse($htdocs, sub {
        my($fullpath, $filename, $is_dir) = @_;
        my $manifest_path = $fullpath;
        $manifest_path =~ s!\\!/!g if $^O eq 'MSWin32';
        $manifest_path =~ s/^$htdocs//;

        for my $qr (@{ $self->{skip} || [] }) {
            return 0 if $filename =~ $qr;
        }
        return 1 if $is_dir;

        $manifest .= $manifest_path;
        if ($self->{use_digest}) {
            open my $fh, '<', $fullpath or die "Can't open file $fullpath: $!";
            $md5->addfile($fh);
        }
        $manifest .= "\n";
        return 1;
    });
    $manifest .= "\n# digest: " . $md5->b64digest . "\n" if $self->{use_digest};

    return $manifest;
}

1;
__END__