File Coverage

blib/lib/HTML/SocialMeta/Base.pm

Criterion	Covered	Total	%
statement	43	47	91.4
branch	8	12	66.6
condition	6	9	66.6
subroutine	10	11	90.9
pod	3	4	75.0
total	70	83	84.3

package HTML::SocialMeta::Base;
use Moo;
use Carp;
our $VERSION = '0.6';

# A list of fields which the cards may possibly use
has [qw(card_type card type name url)] => (
    is      => 'rw',
    lazy    => 1,
    default => q{},
);

has [
    qw(site fb_app_id site_name title description image creator operatingSystem app_country app_name app_id app_url player player_height player_width)
  ] => (
    is      => 'ro',
    lazy    => 1,
    default => q{},
  );

# default should be overridden by sub-classes
has [qw(card_options build_fields)] => (
    is      => 'ro',
    default => sub { {} },
);

sub create {
    my ( $self, $card_type ) = @_;

    $card_type ||= $self->card_type;

    if ( my $option = $self->card_options->{$card_type} ) {

        return $self->$option;
    }

    return $self->_no_card_type($card_type);
}

sub build_meta_tags {
    my ( $self, $field_type ) = @_;

    my @meta_tags;

    if ( $self->meta_attribute eq q{itemprop} ) {
        push @meta_tags, $self->item_type;
    }

    foreach my $field ( $self->required_fields($field_type) ) {

        # check the field has a value set
        $self->_validate_field_value($field);

        push @meta_tags, $self->_generate_meta_tag($field);
    }

    return join "\n", @meta_tags;
}

sub required_fields {
    my ( $self, $field ) = @_;

    return
      exists $self->build_fields->{$field}
      ? @{ $self->build_fields->{$field} }
      : ();
}

sub _validate_field_value {
    my ( $self, $field ) = @_;

    # look to see we have the fields attribute set
    croak q{you have not set this field value } . $field
      if !$self->$field;

    return;
}

sub _generate_meta_tag {
    my ( $self, $field ) = @_;

    # fields that don't start with app or player generate a single tag
    return $self->_build_field( { field => $field } )
      if $field !~ m{(?:app|player|fb)}xms;

    # fields that start with app or player generate multiple tags
    my @tags = ();

    for ( @{ $self->_convert_field($field) } ) {
        push @tags, $self->_build_field( { field => $field, %{$_} } );
    }

    return @tags;
}

sub _build_field {
    my ( $self, $args ) = @_;

    my $field_type = $args->{field_type} || $args->{field};
    my $meta_namespace =
      $args->{ignore_meta_namespace} || $self->meta_namespace;
    my $field = $args->{field};

    return sprintf q{},
      $self->meta_attribute, $meta_namespace, $field_type, $self->$field;
}

sub _convert_field {
    my ( $self, $field ) = @_;

    $field =~ tr/_/:/;

    return $self->provider_convert($field);
}

sub meta_option {
    my ( $self, $card_type ) = @_;

    if ( my $option = $self->card_options->{$card_type} ) {

        # remove create_ and we have the card type
        $option =~ s{^create_}{}xms;
        return $option;
    }
}

sub _no_card_type {
    my ( $self, $card_type ) = @_;
    return croak
q{this card type does not exist try one of these summary, featured_image, app, player};
}

#
# The End
#
__PACKAGE__->meta->make_immutable;

1;

__END__