File Coverage

lib/Gtk2/Ex/MindMapView/Layout/Cluster.pm

Criterion	Covered	Total	%
statement	18	70	25.7
branch	0	14	0.0
condition			n/a
subroutine	6	13	46.1
pod	4	4	100.0
total	28	101	27.7

package Gtk2::Ex::MindMapView::Layout::Cluster;

our $VERSION = '0.000001';

use warnings;
use strict;
use Carp;

use List::Util;

use Gtk2::Ex::MindMapView::Layout::Group;

use base 'Gtk2::Ex::MindMapView::Layout::Group';


# $cluster = Gtk2::Ex::MindMapView::Layout::Cluster->new();

sub new
{
    my $class = shift(@_);

    my $self = $class->SUPER::new(@_);

    if (!defined $self->{cluster_no})
    {
	croak "Gtk2::Ex::MindMapView::Layout::Cluster requires a 'cluster_no'\n";
    }

    $self->{items} = [];  # Array of view items.

    return $self;
}


# $cluster->add($item)

sub add
{
    my ($self, $item) = @_;

    push @{$self->{items}}, $item;

    my $column = $self->get('column');

    my @items = @{$self->{items}};

    $self->set(height=>_cluster_height($self, \@items));

    $self->set(width=>_cluster_width($self, \@items));
}


# $cluster->layout();

sub layout
{
    my $self = shift(@_);

    my $column = $self->get('column');

    my ($x, $y) = $self->get(qw(x y));

    my $column_no = $column->get('column_no');

    my $column_width = $column->get('width');

    my @visible_items = grep { $_->is_visible(); } @{$self->{items}};

    return if (scalar @visible_items == 0);

    foreach my $item (@visible_items)
    {
	my ($item_height, $item_width) = $item->get(qw(height width));

	my $justification = _justification($column_no, $column_width, $item_width);

	$item->set(x=>($x + $justification));

	$item->set(y=>$y);

	$y += ($item_height + $self->get_vertical_padding());
    }
}


sub seq_no
{
    my $self = shift(@_);

    my $predecessor_item = $self->{predecessor};

    return (defined $predecessor_item) ? $predecessor_item->get('y') : $self->{cluster_no};
}


sub _cluster_height
{
    my ($self, $items_ref) = @_;

    my @visible_items = grep { $_->is_visible(); } @$items_ref;

    return 0 if (scalar @visible_items == 0);

    my $total_height = List::Util::sum (map { $_->get('height'); } @visible_items);

    my $total_pad = ($#visible_items * $self->get_vertical_padding());

#    print "Cluster, height: $total_height  pad: $total_pad  visible_items: @visible_items\n";

    return ($total_height + $total_pad);
}


sub _cluster_width
{
    my ($self, $items_ref) = @_;

    my @visible_items = grep { $_->is_visible(); } @$items_ref;

    return 0 if (scalar @visible_items == 0);

    my $max_width = List::Util::max (map { $_->get('width'); } @$items_ref);

    my $width = List::Util::min($max_width, $self->get_max_width());

#    print "Cluster, max_width: $max_width  width: $width  visible_items: @visible_items\n";

    return $width;
}


sub _justification
{
    my ($column_no, $column_width, $item_width) = @_;

    return 0 if ($column_no > 0);

    return ($column_width - $item_width) if ($column_no < 0);

    return (($column_width - $item_width) / 2);
}



1; # Magic true value required at end of module
__END__