File Coverage

blib/lib/Git/RemoteURL/Parse.pm

Criterion	Covered	Total	%
statement	23	23	100.0
branch	8	8	100.0
condition			n/a
subroutine	5	5	100.0
pod	1	1	100.0
total	37	37	100.0

package Git::RemoteURL::Parse;

use 5.010;
use strict;
use warnings;

use Exporter 'import';
our @EXPORT_OK = qw(parse_git_remote_url);

our $VERSION = '0.05';

sub parse_git_remote_url {
    my ($url) = @_;

    # --- GitHub HTTPS URLs ---
    if ($url =~ m{^https://
                  (?:[^@]+@)?            # optional user:token@
                  github\.com/
                  ([\w.-]+)              # username
                  /([\w.-]+?)            # repo
                  (?:\.git)?$
               }x
       ) {
      return { service => 'github', user => $1, repo => $2 };
    }

    # --- GitHub SSH URLs ---
    elsif ($url =~ m{^git@
                     (github\.com|gh[-\w]+) # host: github.com or gh-alias
                     :
                     ([\w.-]+)              # username
                     /([\w.-]+?)            # repo
                     (?:\.git)?$
                  }x
          ) {
      return { service => 'github', user => $2, repo => $3 };
    }

    # --- GitLab HTTPS URLs ---
    if ($url =~ m{^https://
                  (?:[^@]+@)?            # optional user:token@
                  gitlab\.com/
                  ((?:[\w.-]+/)+)        # group path (at least one level, trailing slash)
                  ([\w.-]+?)             # repo
                  (?:\.git)?$
               }x
       ) {
      my ($groups, $repo) = ($1, $2);
      $groups =~ s!/$!!;
      return { service => 'gitlab', group_path => $groups, repo => $repo };
    }

    # --- GitLab SSH URLs ---
    elsif ($url =~ m{^git@
                     (gitlab\.com|gl[-\w]+) # host: gitlab.com or gl-alias
                     :
                     ((?:[\w.-]+/)+)        # group path with trailing slash
                     ([\w.-]+?)             # repo
                     (?:\.git)?$
                  }x
          ) {
      my ($groups, $repo) = ($2, $3);
      $groups =~ s!/$!!;
      return { service => 'gitlab', group_path => $groups, repo => $repo };
    }
    return;   # No match
}



1; # End of Git::RemoteURL::Parse

__END__